iniciar-programa
    define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion orientar como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si frente-bloqueado entonces inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            mientras no-orientado-al-oeste hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-derecha;
            si frente-libre entonces avanza;
            si algun-zumbador-en-la-mochila entonces inicio
                deja-zumbador;
            fin
            sino inicio
                mientras junto-a-zumbador hacer coge-zumbador;
            fin;
            si ningun-zumbador-en-la-mochila entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                apagate;
            fin;
            mientras no-orientado-al-sur hacer gira-izquierda;
            si frente-libre entonces avanza;
        fin;
    fin;

    define-nueva-instruccion ir-a-cima como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        si no-junto-a-zumbador entonces inicio
            gira-izquierda;
            gira-izquierda;
            si frente-libre entonces avanza;
            gira-izquierda;
        fin
        sino gira-derecha;
    fin;

    define-nueva-instruccion erosion como inicio
        coge-zumbador;
        si frente-libre entonces avanza;
        gira-derecha;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        gira-izquierda;
        gira-izquierda;
        avanza;
        deja-zumbador;
        gira-izquierda;
        gira-izquierda;
        si frente-libre entonces avanza;
        gira-izquierda;
    fin;

    define-nueva-instruccion talvez-erosion como inicio
        si frente-libre entonces avanza;
        gira-derecha;
        si no-junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    si frente-libre entonces inicio
                        avanza;
                        mientras no-junto-a-zumbador y frente-libre hacer avanza;
                        si junto-a-zumbador entonces inicio
                            gira-derecha;
                            si frente-libre entonces avanza;
                            ir-a-cima;
                            erosion;
                        fin;
                    fin;
                fin
                sino inicio
                    gira-izquierda;
                fin;
            fin;
        fin
        sino inicio
            mientras frente-libre hacer avanza;
            gira-izquierda;
        fin;
    fin;

    inicia-ejecucion
        mientras algun-zumbador-en-la-mochila hacer inicio
            orientar;
            mientras frente-libre hacer inicio
            si junto-a-zumbador y orientado-al-este entonces inicio
                si derecha-bloqueada entonces ir-a-cima;
                si frente-bloqueado entonces inicio
                    orientar;
                fin
                sino inicio
                    talvez-erosion;
                fin;
            fin;
            fin;
            si frente-bloqueado y no-junto-a-zumbador entonces inicio
                si algun-zumbador-en-la-mochila entonces orientar;
            fin;
            si ningun-zumbador-en-la-mochila entonces inicio
                mientras no-orientado-al-norte hacer gira-izquierda;
                si frente-libre entonces inicio
                    avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    apagate;
                fin
                sino inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    apagate;
                fin;
            fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
