iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion deja (n) como inicio
        repetir n veces inicio
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion ubica1 como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira (2);
    fin;
    define-nueva-instruccion UnoAUno como inicio
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
            avanza;
            deja-zumbador;
            gira (2);
            avanza;
            gira (2);
        fin;
    fin;
    define-nueva-instruccion recorrer como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recorrer;
            deja-zumbador;
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                    gira (2);
                fin
                sino inicio
                    recorrer;
                    avanza;
                fin;
            fin
            sino inicio
                gira (2);
            fin;
        fin;
    fin;
    define-nueva-instruccion ordena (n) como inicio
        si orientado-al-norte y junto-a-zumbador entonces inicio
            coge-zumbador;
            ordena (sucede (n));
        fin
        sino inicio
            si orientado-al-norte entonces inicio
                deja (n);
            fin;
            mientras no-orientado-al-este hacer inicio
                gira-izquierda;
            fin;
            avanza;
            si junto-a-zumbador entonces inicio
                repetir n veces inicio
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        gira-izquierda;
                        avanza;
                        deja-zumbador;
                        gira (2);
                        avanza;
                        gira-izquierda;
                    fin;
                fin;
                si junto-a-zumbador entonces inicio
                    gira-izquierda;
                    avanza;
                    mientras junto-a-zumbador hacer inicio
                        coge-zumbador;
                    fin;
                    gira (2);
                    avanza;
                    gira (2);
                    deja (n);
                    ordena (0);
                fin
                sino inicio
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                    UnoAUno;
                    avanza;
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                    UnoAUno;
                    gira-izquierda;
                    avanza;
                    gira (2);
                    UnoAUno;
                    avanza;
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                    ordena (0);
                fin;
            fin
            sino inicio
                gira (2);
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                gira (2);
            fin;
        fin;
    fin;
    define-nueva-instruccion ordenar (x) como inicio
        si junto-a-zumbador entonces inicio
            avanza;
            ordenar (sucede (x));
        fin
        sino inicio
            gira (2);
            avanza;
            recorrer;
            ubica1;
            repetir x veces inicio
                gira-izquierda;
                si junto-a-zumbador entonces inicio
                    ordena (0);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion sumar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sumar;
            si orientado-al-este entonces inicio
                deja-zumbador;
            fin;
        fin
        sino inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                gira-izquierda;
            fin;
        fin;
    fin;
    define-nueva-instruccion anexar (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            anexar (sucede (n));
        fin
        sino inicio
            deja (n);
            ubica1;
            gira-izquierda;
            avanza;
            avanza;
            deja (n);
            gira (2);
            avanza;
            avanza;
            gira-izquierda;
            avanza;
            mientras junto-a-zumbador hacer inicio
                avanza;
            fin;
            gira (2);
            avanza;
            recorrer;
            ubica1;
            gira-izquierda;
            ordena (0);
        fin;
    fin;
    define-nueva-instruccion CostoMinimo como inicio
        ordenar (0);
        mientras junto-a-zumbador hacer inicio
            sumar;
            si junto-a-zumbador entonces inicio
                anexar (0);
            fin;
        fin;
        ubica1;
        gira-izquierda;
        avanza;
        avanza;
        gira (2);
        UnoAUno;
    fin;
    inicia-ejecucion
        CostoMinimo;
        apagate;
    termina-ejecucion
finalizar-programa
