iniciar-programa
  define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
  define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
  define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
  define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
  define-nueva-instruccion al-frente como mientras frente-libre hacer avanza;


  define-nueva-instruccion compara(n) como inicio
      si junto-a-zumbador y no si-es-cero (n) entonces inicio
          coge-zumbador;
          compara(precede(n));
          deja-zumbador;
          repetir 2 veces gira-izquierda;
          avanza;
          deja-zumbador;
          repetir 2 veces gira-izquierda;
          avanza;
      fin sino inicio
          si si-es-cero (n) entonces inicio
              (*MAYOR EN EL QUE ESTOY*)
          fin sino inicio
              (*ES MAYOR EL QUE TRAIGO*)
              repetir n veces deja-zumbador;
          fin;
      fin;
  fin;
  define-nueva-instruccion en-orden(n) como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          en-orden(sucede(n));
      fin sino inicio
          si frente-libre entonces avanza;
          compara(n);
      fin;
  fin;
  define-nueva-instruccion repite (n) como inicio
      si no si-es-cero (precede(n)) entonces inicio
          repetir precede(n) veces en-orden(0);
          este;
          mientras junto-a-zumbador hacer avanza;
          repetir 2 veces gira-izquierda;
          si frente-libre entonces avanza;
          repite (precede(n));
      fin sino inicio

      fin;
  fin;
  define-nueva-instruccion contar (n) como inicio
      si junto-a-zumbador entonces inicio
          si frente-libre entonces avanza;
          contar(sucede(n));
      fin sino inicio
              (* N ES EL LARGO DE MI FILA A ORDENAR*)
          si no si-es-cero (n) entonces inicio

          si no si-es-cero (precede(n)) entonces inicio
              repetir 2 veces gira-izquierda;
              si frente-libre entonces avanza;
              repite(n);
          fin sino inicio
                  (*YA SOLO QUEDA UN NUMERO*)
          fin;

          fin;
      fin;
  fin;
  define-nueva-instruccion ordenar como inicio
      contar(0);
  fin;

  define-nueva-instruccion suma-ultimos como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          suma-ultimos;
          deja-zumbador;
      fin sino inicio
          si frente-libre entonces avanza;
      fin;
  fin;

  define-nueva-instruccion copia(n) como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          copia(sucede(n));
      fin sino inicio
          repetir n veces deja-zumbador;
          norte;
          si frente-libre entonces avanza;
          oeste;
          al-frente;
          este;
          mientras junto-a-zumbador hacer avanza;
          repetir n veces deja-zumbador;
          sur;
          si frente-libre entonces avanza;
          oeste;
          al-frente;
          este;
      fin;
  fin;

  define-nueva-instruccion suma-todos como inicio
      norte;
      si frente-libre entonces avanza;
      este;
      mientras junto-a-zumbador hacer avanza;
      oeste;
      si frente-libre entonces avanza;
      mientras frente-libre hacer inicio
          suma-ultimos;
      fin;
  fin;
  define-nueva-instruccion proceso como inicio
      mientras no-orientado-al-sur hacer inicio
          ordenar;
          suma-ultimos;
          copia(0);
          mientras junto-a-zumbador hacer avanza;
          oeste;
          si frente-libre entonces avanza;
          si frente-bloqueado entonces inicio
              sur;
          fin sino inicio
              al-frente;
              este;
          fin;
      fin;
      suma-todos;
  fin;
    inicia-ejecucion
        proceso;
        apagate;
    termina-ejecucion
finalizar-programa
