iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;

define-nueva-instruccion ordena(n) como inicio
    este;
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        ordena(sucede(n));
    fin sino inicio
        si frente-libre entonces inicio
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
            si junto-a-zumbador entonces inicio
                ordena(0);
            fin;
        fin;
        oeste;
        mientras frente-libre hacer avanza;
        este;
        repetir precede(n) veces avanza;
        deja-zumbador;
    fin;
fin;

define-nueva-instruccion toma(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        toma(n);
        repetir n veces deja-zumbador;
        si frente-libre entonces avanza;
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            toma(sucede(n));
        fin sino inicio
            oeste;
            mientras frente-libre hacer avanza;
            este;
        fin;
    fin;
fin;

define-nueva-instruccion suma(n) como inicio
    si (junto-a-zumbador) y (orientado-al-oeste o orientado-al-sur) entonces inicio
        coge-zumbador;
        suma(sucede(n));
        si orientado-al-sur entonces inicio
            norte;
            avanza;
            repetir sucede(n) veces deja-zumbador;
            sur;
            avanza;
            norte;
        fin;
        deja-zumbador;
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            gira-izquierda;
            suma(n);
        fin;
    fin;
fin;

define-nueva-instruccion sube como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        sube;
        deja-zumbador;
    fin sino inicio
        norte;
        avanza;
        oeste;
    fin;
fin;

define-nueva-instruccion min como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        min;
        deja-zumbador;
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            min;
        fin;
    fin;
fin;

    inicia-ejecucion
    ordena(0);
    oeste;
    avanzar;
    este;
    toma(1);
    oeste;
    si no-junto-a-zumbador entonces inicio
        avanza;
    fin;
    mientras junto-a-zumbador y frente-libre hacer inicio
        si frente-libre entonces inicio
            suma(0);
            oeste;
            si frente-libre entonces inicio
                avanzar;
                este;
                ordena(0);
                oeste;
                avanzar;
                este;
                toma(1);
                oeste;
                si no-junto-a-zumbador entonces inicio
                    avanza;
                fin;
            fin sino inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                norte;
                avanza;
                oeste;
            fin;
        fin sino inicio
            si izquierda-bloqueada entonces inicio
                sube;
            fin;
        fin;
    fin;
    este;
    avanzar;
    oeste;
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
    min;

        apagate;
    termina-ejecucion
finalizar-programa
