iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion quita(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(n);
            coge-zumbador;
        fin sino inicio
            oeste;
            avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
        norte;
        repetir n veces inicio
            si junto-a-zumbador y no orientado-al-sur entonces inicio
                coge-zumbador;
            fin sino inicio
                sur;
                deja-zumbador;
            fin;
        fin;
        si orientado-al-norte entonces inicio
            oeste;
            avanza;
            repetir n veces deja-zumbador;
            este;
            avanza;
            repetir n veces deja-zumbador;
        fin sino inicio
            quita(n);
            este;
            avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion ordena(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordena(sucede(n));
        fin sino inicio
            este;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    compara(n);
                fin sino inicio
                    oeste;
                    avanza;
                    repetir n veces deja-zumbador;
                    mientras frente-libre hacer avanza;
                fin;
            fin sino inicio
                repetir n veces deja-zumbador;
                oeste;
                mientras frente-libre hacer avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador y no orientado-al-oeste entonces inicio
            si frente-libre entonces inicio
                avanza;
                cuenta(sucede(n));
            fin sino inicio
                oeste;
                cuenta(sucede(n));
            fin;
        fin sino inicio
            oeste;
            mientras frente-libre hacer avanza;
            este;
            repetir n veces inicio
                mientras junto-a-zumbador y no orientado-al-oeste hacer inicio
                    ordena(0);
                fin;
                este;
            fin;
        fin;
    fin;

    define-nueva-instruccion ordenar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordenar;
            deja-zumbador;
        fin sino inicio
            oeste;
            mientras frente-libre hacer avanza;
            este;
            mientras junto-a-zumbador y frente-libre hacer avanza;
        fin;
    fin;

    define-nueva-instruccion suma2(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            suma2(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            oeste;
            avanza;
            norte;
            avanza;
            repetir n veces deja-zumbador;
            sur;
            avanza;
            este;
            mientras no orientado-al-oeste hacer inicio
                mientras junto-a-zumbador y frente-libre hacer avanza;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                si frente-bloqueado y no junto-a-zumbador entonces inicio
                    oeste;
                    mientras frente-libre hacer avanza;
                fin sino inicio
                    ordenar;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion suma(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            suma(sucede(n));
        fin sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
                suma2(n);
            fin sino inicio
                apagate;
            fin;
        fin;
    fin;

    inicia-ejecucion
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
        mientras no orientado-al-oeste hacer inicio
            cuenta(0);
            suma(0);
            este;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
