iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        oeste;
        si no-junto-a-zumbador entonces inicio
            avanza;
        fin;
        mientras frente-libre y junto-a-zumbador hacer inicio
            avanza;
        fin;
        este;
        si no-junto-a-zumbador entonces inicio
            mientras no-junto-a-zumbador y frente-libre hacer inicio
                avanzA;
            fin;
        fin;
    fin;

    define-nueva-instruccion juntar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            juntar(sucede(n));
        fin sino inicio
            si orientado-al-este entonces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
                avanza;
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin sino inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
                este;
                avanza;
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion tomar(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar(precede(n));
        fin sino inicio
            si si-es-cero(n) entonces inicio
                oeste;
                avanza;
                juntar(0);
            fin sino inicio
                oeste;
                avanzA;
                repetir n veces inicio
                    coge-zumbador;
                fin;
                este;
                juntar(0);
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            comparar(sucede(n));
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            avanza;
            si junto-a-zumbador entonces inicio
                tomar(n);
            fin sino inicio
                apagate;
            fin;
        fin;
    fin;

    define-nueva-instruccion minimo(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            minimo(sucede(n));
        fin sino inicio
            oeste;
            repetir n veces inicio
                deja-zumbador;
            fin;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            norte;
            avanzA;
            repetir n veces inicio
                deja-zumbador;
            fin;
            sur;
            avanza;
            este;
            mientras frente-libre y no-junto-a-zumbador hacer inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion costo(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            costo(sucede(n));
        fin sino inicio
            avanza;
            repetir n veces inicio
                deja-zumbador;
            fin;
            minimo(0);
        fin;
    fin;

    define-nueva-instruccion ordenar(m) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            ordenar(sucede(m));
        fin sino inicio
            ir11;
            si no si-es-cero (precede(m)) entonces inicio
                repetir precede(m) veces inicio
                    repetir precede(m) veces inicio
                        comparar(0);
                    fin;
                    ir11;
                fin;
                costo(0);
                ordenar(0);
            fin;
        fin;
    fin;

    inicia-ejecucion
        ordenar(0);
        apagate;
    termina-ejecucion
finalizar-programa
