iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion pasar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasar(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion tomar(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar(precede(n));
        fin sino inicio
            si si-es-cero(n) entonces inicio
                oeste;
                avanza;
                pasar(0);
            fin;
            si no si-es-cero(n) entonces inicio
                oeste;
                avanza;
                pasar(0);
                oeste;
                avanza;
                repetir n veces inicio
                    coge-zumbador;
                fin;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion ordenar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordenar(sucede(n));
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            avanzA;
            si junto-a-zumbador entonces inicio
                tomar(n);
            fin;
        fin;
    fin;

    define-nueva-instruccion contar como inicio
        si junto-a-zumbador entonces inicio
            avanzA;
            contar;
            mientras junto-a-zumbador hacer inicio
                ordenar(0);
            fin;
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
        fin sino inicio
            oeste;
            mientras frente-libre hacer inicio
                avanzA;
            fin;
            este;
        fin;
    fin;

    define-nueva-instruccion sumar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sumar(sucede(n));
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            oeste;
            mientras frente-libre hacer inicio
                avanzA;
            fin;
            norte;
            avanza;
            repetir n veces inicio
                deja-zumbador;
            fin;
            sur;
            avanza;
            este;
            mientras no junto-a-zumbador hacer inicio
                avanza;
            fin;
            mientras junto-a-zumbador hacer inicio
                ordenar(0);
            fin;
            oeste;
            avanza;
            mientras junto-a-zumbador hacer inicio
                avanza;
            fin;
            este;
            avanzA;
        fin;
    fin;

    define-nueva-instruccion costo-minimo(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            costo-minimo(sucede(n));
        fin sino inicio
            avanzA;
            repetir n veces inicio
                deja-zumbador;
            fin;
            sumar(0);
        fin;
    fin;

    define-nueva-instruccion contar2(n) como inicio
        si junto-a-zumbador entonces inicio                           
            avanza;
            contar2(sucede(n));
        fin sino inicio
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
            repetir precede(n) veces inicio
                costo-minimo(0);
            fin;
        fin;
    fin;

    inicia-ejecucion
        contar;
        contar2(0);
        apagate;
    termina-ejecucion
finalizar-programa
