iniciar-programa

    define-nueva-instruccion g(n) como
    inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion cosa(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            cosa(n);
            deja-zumbador;
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            g(2);
            avanza;
            g(2);
        fin;
    fin;
    define-nueva-instruccion int(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            int(sucede(n));
        fin
        sino
        inicio
            avanza;
            cosa(n);
        fin;
    fin;
    define-nueva-instruccion compara(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            avanza;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                g(2);
                avanza;
                g(2);
                compara(sucede(n));
            fin
            sino
            inicio
                repetir n veces
                    deja-zumbador;
                g(2);
                avanza;
                g(2);
                repetir sucede(n) veces
                    deja-zumbador;
                avanza;
            fin;
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            avanza;
            repetir n veces
                deja-zumbador;
            g(2);
            avanza;
            g(2);
            int(0);
            avanza;
        fin;
    fin;
    define-nueva-instruccion lleva(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            lleva(sucede(n));
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            mientras frente-libre hacer
                avanza;
            g(3);
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion suma como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            suma;
            deja-zumbador;
        fin
        sino
        inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion ordena(n) como
    inicio
        si no si-es-cero (precede(n)) entonces
        inicio
            repetir n veces
            inicio
                repetir n veces
                inicio
                    compara(0);
                fin;
                g(2);
                mientras frente-libre hacer
                    avanza;
                g(2);
            fin;
            mientras junto-a-zumbador hacer
                avanza;
            g(2);
            avanza;
            suma;
            lleva(0);
            g(2);
            avanza;
            g(1);
            ordena(precede(n));
        fin;
    fin;
    define-nueva-instruccion cuenta(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            avanza;
            cuenta(sucede(n));
        fin
        sino
        inicio
            g(2);
            mientras frente-libre hacer
                avanza;
            g(2);
            ordena(n);
        fin;
    fin;
    inicia-ejecucion
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
