iniciar-programa

    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion mover como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mover;
            deja-zumbador;
        fin sino inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion comparar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                gira(2);
                avanza;
                gira(2);
                comparar;
                deja-zumbador;
                avanza;
                deja-zumbador;
                gira(2);
                avanza;
                gira(2);
            fin sino inicio
                deja-zumbador;
                gira(2);
                avanza;
                gira(2);
                mover;
                gira(2);
                avanza;
                gira(2);
            fin;
        fin;
    fin;

    define-nueva-instruccion sumar(beepers) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sumar(sucede(beepers));
        fin sino inicio
            repetir beepers veces deja-zumbador;
            gira(1);
            avanza;
            gira(1);
            mientras frente-libre hacer avanza;
            repetir beepers veces deja-zumbador;
            gira(1);
            avanza;
            gira(1);
            mientras no-junto-a-zumbador hacer avanza;
        fin;
    fin;

    define-nueva-instruccion contar_elementos(x) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            contar_elementos(sucede(x));
            si no(si-es-cero(x)) entonces inicio
                repetir x veces inicio
                    repetir x veces inicio
                        comparar;
                        avanza;
                    fin;
                    gira(2);
                    mientras frente-libre hacer avanza;
                    gira(2);
                    mientras no-junto-a-zumbador hacer avanza;
                fin;
                mover;
                sumar(0);
            fin;
        fin sino inicio
            gira(2);
            repetir x veces inicio
                repetir x veces inicio
                    comparar;
                    avanza;
                fin;
                gira(2);
                mientras frente-libre hacer avanza;
                gira(2);
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
            fin;
            mover;
            sumar(0);
        fin;
    fin;

    inicia-ejecucion
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        si no-junto-a-zumbador y frente-libre entonces avanza;
        contar_elementos(0);
        apagate;
    termina-ejecucion
finalizar-programa
