iniciar-programa
define-nueva-instruccion recoge-cuenta como   (*recoge todos los zumbadores de arriba*)
inicio
mientras no-orientado-al-norte hacer
gira-izquierda;
si frente-libre entonces
avanza;
mientras no-orientado-al-oeste hacer
gira-izquierda;
mientras frente-libre hacer
    inicio
    si junto-a-zumbador entonces
        mientras junto-a-zumbador hacer
        coge-zumbador;
    avanza;
    si junto-a-zumbador entonces
        mientras junto-a-zumbador hacer
        coge-zumbador;
    fin;
mientras no-orientado-al-norte hacer   (*va a dejar un zumbador para conteo*)
gira-izquierda;
si frente-libre entonces
avanza;
si algun-zumbador-en-la-mochila entonces
deja-zumbador;
si frente-libre entonces
avanza;
mientras algun-zumbador-en-la-mochila hacer
deja-zumbador;      (*deja todos los que sobra para quedar vacio  y regresar*)
gira-izquierda;
gira-izquierda;
mientras frente-libre hacer
avanza;
mientras no-orientado-al-oeste hacer
gira-izquierda;
si frente-libre entonces
avanza;
mientras no-orientado-al-este hacer  (*colocamos a karel como al incio *)
gira-izquierda;
fin;


define-nueva-instruccion sube  como (*coloca los zumbadores arrriba para conteo*)
inicio
mientras no-orientado-al-norte hacer
gira-izquierda;
avanza;
mientras algun-zumbador-en-la-mochila hacer
deja-zumbador;
mientras no-orientado-al-sur hacer
gira-izquierda;
avanza;
mientras no-orientado-al-este hacer
gira-izquierda;
fin;

define-nueva-instruccion compara-todos(n) como
inicio
repetir n veces
    inicio
        si junto-a-zumbador entonces
        coge-zumbador;
    fin;
    si junto-a-zumbador entonces
        inicio
        coge-zumbador;
        si no-junto-a-zumbador entonces
        sube;
        fin;
    mientras algun-zumbador-en-la-mochila hacer
    deja-zumbador;
    si frente-libre entonces
    avanza;
 fin;



define-nueva-instruccion compara(n) como
inicio
    si no si-es-cero(n) entonces
    inicio
        mientras frente-libre hacer
            inicio
            mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
            compara-todos(n);
            fin;
    compara-todos(n);   (*compara el ultimo que no fue comparado*)
    recoge-cuenta;   (*recoge los zumbadores de arriba y asigna un 1 por tipos de viga*)
    compara(precede(n));
    fin;
    mientras frente-libre y no junto-a-zumbador hacer (*recoge las vigas de altura-1*)
        inicio
    avanza;
    si junto-a-zumbador entonces
    coge-zumbador;
        fin;
fin;

define-nueva-instruccion recoge-vigas como   (*recoge todos los zumbadores de las vigas*)
inicio
mientras no-orientado-al-norte hacer
gira-izquierda;
mientras frente-libre y junto-a-zumbador hacer
inicio
coge-zumbador;
avanza;
fin;
gira-izquierda;
gira-izquierda;
si junto-a-zumbador entonces
coge-zumbador;
mientras frente-libre hacer
avanza;
mientras algun-zumbador-en-la-mochila hacer
deja-zumbador;
mientras no-orientado-al-este hacer
gira-izquierda;
fin;


define-nueva-instruccion mide(n) como
inicio
si frente-libre entonces
    inicio
    avanza;
    mide(sucede(n));(*aumenta 1 por cada paso para saber la altura*)
    fin
    sino
    inicio
    mientras no-orientado-al-sur hacer
    gira-izquierda;
    mientras frente-libre hacer
    avanza;
    mientras no-orientado-al-oeste hacer
    gira-izquierda;
    avanza;
    mientras no-orientado-al-este hacer
    gira-izquierda;
    compara(n);  (*compara la vigas de altura n*)
    fin;
fin;
    inicia-ejecucion
    mientras no-orientado-al-este hacer
    gira-izquierda;
    mientras frente-libre hacer   (*recorre las vigas y las corta*)
    inicio
        avanza;
        si junto-a-zumbador entonces
        recoge-vigas;
    fin;

    mientras no-orientado-al-oeste hacer (*regresa al inicio*)
    gira-izquierda;
    mientras frente-libre hacer
    avanza;

    mientras no-orientado-al-este hacer  (*mide la altura de la pared*)
    gira-izquierda;
    avanza;
    mientras no-orientado-al-norte hacer
    gira-izquierda;
    mide(1);
    mientras no-orientado-al-oeste hacer  (*regresa a recoger la cuenta*)
    gira-izquierda;
    mientras frente-libre hacer
    avanza;
    mientras no-orientado-al-este hacer
    gira-izquierda;
    avanza;
    mientras no-orientado-al-norte hacer
    gira-izquierda;
    si frente-libre entonces
    avanza;
    si frente-libre entonces
    avanza;
    si algun-zumbador-en-la-mochila entonces
    deja-zumbador;
    si frente-libre entonces
    avanza;
    mientras algun-zumbador-en-la-mochila hacer
    deja-zumbador;
    mientras no-orientado-al-sur hacer
    gira-izquierda;
    si frente-libre entonces
    avanza;
    mientras junto-a-zumbador hacer
    coge-zumbador;
    mientras frente-libre hacer
    avanza;
    mientras no-orientado-al-oeste hacer
    gira-izquierda;
    avanza;
    mientras algun-zumbador-en-la-mochila hacer
    deja-zumbador;
        si no-junto-a-zumbador entonces   (*en un mundo minimo tiene que comprobar*)
        mientras no-orientado-al-este hacer
        gira-izquierda;
        si frente-libre entonces
        avanza;
        mientras no-orientado-al-norte hacer
        gira-izquierda;
        mientras frente-libre y no-junto-a-zumbador hacer
        avanza;
        si junto-a-zumbador entonces
        coge-zumbador;
        mientras no-orientado-al-sur hacer
        gira-izquierda;
        mientras frente-libre hacer
        avanza;
        mientras no-orientado-al-oeste hacer
        gira-izquierda;
        mientras frente-libre hacer
        avanza;
        si algun-zumbador-en-la-mochila entonces
        deja-zumbador;



        apagate;
    termina-ejecucion
finalizar-programa 