iniciar-programa

    define-nueva-instruccion gira (n) como inicio
      repetir n veces inicio
        gira-izquierda;
      fin;
    fin;


    define-nueva-instruccion quita-viga como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        si frente-libre entonces inicio
          avanza;
          quita-viga;
          si orientado-al-sur entonces inicio
            gira (2);
          fin;
          avanza;
        fin;
      fin;
    fin;

    define-nueva-instruccion busca-la-altura como inicio
      si orientado-al-norte entonces inicio
        gira (3);
        mientras frente-libre hacer inicio
          avanza;
          si no-junto-a-zumbador entonces inicio
            gira (3);
            avanza;
            si junto-a-zumbador entonces inicio
              quita-viga;
              si frente-libre entonces inicio
                avanza;
              fin;
              si orientado-al-norte entonces inicio
                gira (3);
              fin;
            fin
            sino inicio
              gira (2);
              avanza;
              gira (3);
            fin;
          fin;
        fin;
      fin;
    fin;

    define-nueva-instruccion vealprincipio como inicio
      si orientado-al-este entonces inicio
        gira (3);
        mientras frente-libre hacer inicio
          avanza;
        fin;
      fin;
      si orientado-al-sur entonces inicio
        gira (3);
        mientras frente-libre hacer inicio
          avanza;
        fin;
      fin;
      gira (2);
    fin;

    define-nueva-instruccion busca-la-altura2 como inicio
      si frente-bloqueado y orientado-al-norte entonces inicio
        gira (3);
        mientras frente-libre y no-junto-a-zumbador hacer inicio
          avanza;
          si junto-a-zumbador entonces inicio
            gira (3);
            quita-viga;
            gira (3);
          fin;
        fin;
      fin;
    fin;

    define-nueva-instruccion quita-vigas-altas como inicio
      avanza;
      gira (1);
      mientras frente-libre hacer inicio
        avanza;
      fin;
      gira (3);
      si junto-a-zumbador entonces inicio
        gira (3);
        quita-viga;
        busca-la-altura2;
        vealprincipio;
        deja-zumbador;
        avanza;
      fin;
      mientras no-junto-a-zumbador y (frente-libre y izquierda-bloqueada) hacer inicio
        avanza;
        si junto-a-zumbador entonces inicio
          gira (3);
          quita-viga;
          busca-la-altura2;
          vealprincipio;
          deja-zumbador;
          avanza;
        fin;
      fin;
      si (no-junto-a-zumbador y orientado-al-este) y ningun-zumbador-en-la-mochila entonces inicio
        vealprincipio;
        avanza;
      fin;
    fin;

    inicia-ejecucion
      quita-vigas-altas;
      mientras no-junto-a-zumbador y frente-libre hacer inicio
        avanza;
      fin;
      mientras junto-a-zumbador hacer inicio
        gira (1);
        mientras junto-a-zumbador hacer inicio
          coge-zumbador;
          si frente-libre entonces inicio
            avanza;
          fin;
        fin;
        busca-la-altura;
        vealprincipio;
        deja-zumbador;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer inicio
          avanza;
        fin;
      fin;
       apagate;
    termina-ejecucion
finalizar-programa
