iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;

define-nueva-instruccion tomar_torre como inicio
    sur;
    mientras frente-libre hacer inicio
        avanza;
        coge-zumbador;
    fin;
    norte;
    mientras no-junto-a-zumbador hacer avanza;
    coge-zumbador;
    este;
fin;

define-nueva-instruccion quitar_iguales como inicio
    norte;
    mientras frente-libre y junto-a-zumbador hacer avanza;
    si no junto-a-zumbador entonces inicio
        sur;
        avanza;
    fin;

    tomar_torre;
    mientras frente-libre hacer inicio
        avanza;
        si junto-a-zumbador entonces inicio
            si izquierda-bloqueada entonces inicio
                tomar_torre;
            fin sino inicio
                norte;
                avanza;
                si no-junto-a-zumbador entonces inicio
                    sur;
                    avanza;
                    tomar_torre;
                fin sino inicio
                    sur;
                    avanza;
                    este;
                fin;
            fin;
        fin;
    fin;
fin;


    inicia-ejecucion
    avanza;
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
    mientras junto-a-zumbador hacer inicio
        quitar_iguales;
        sur;
        avanzar;
        oeste;
        avanzar;
        deja-zumbador;
        este;
        avanza;
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
