iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion acomoda como inicio
        mientras frente-libre hacer inicio
            mientras junto-a-zumbador hacer inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                si frente-libre entonces avanza;
                si no-junto-a-zumbador entonces inicio
                    gira-izquierda;
                    gira-izquierda;
                    avanza;
                    este;
                fin;
                si junto-a-zumbador y frente-bloqueado entonces inicio
                    este;
                    coge-zumbador;
                    mientras frente-libre hacer avanza;
                fin;
            fin;
            mientras frente-libre hacer avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            sur;
            mientras frente-libre hacer avanza;
            oeste;
            avanza;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            norte;
        fin;
    fin;
    define-nueva-instruccion cuenta-vigas como inicio
        este;
        mientras frente-libre hacer avanza;
        norte;
        mientras no-orientado-al-sur hacer inicio
            si junto-a-zumbador entonces coge-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion resultado como inicio
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    fin;
    inicia-ejecucion
        mientras frente-libre hacer avanza;
        norte;
        acomoda;
        cuenta-vigas;
        resultado;
        apagate;
    termina-ejecucion
finalizar-programa
