iniciar-programa
    define-nueva-instruccion Norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion Sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;

    define-nueva-instruccion Este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion Oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion tomaYdeja como inicio
        mientras frente-libre hacer inicio
            avanza;
            mientras junto-a-zumbador hacer inicio
                Norte;
                coge-zumbador;
                si frente-libre entonces avanza;
           fin;
           Sur;
           mientras frente-libre hacer avanza;
           mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
           Este;
        fin;
    fin;

    define-nueva-instruccion regresa como inicio
        Oeste;
        mientras frente-libre hacer avanza;
        Este;
        si algun-zumbador-en-la-mochila entonces deja-zumbador;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        si no si-es-cero(n) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                comparar(precede(n));
                si algun-zumbador-en-la-mochila entonces deja-zumbador;
            fin;
        fin
        sino inicio
            si no-junto-a-zumbador entonces inicio
                Norte;
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                Sur;
                avanza;
                Este;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(n));
        fin
        sino inicio
            repetir n veces deja-zumbador;
            mientras frente-libre hacer inicio
                si frente-libre entonces avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                si junto-a-zumbador entonces comparar(n);
            fin;
        fin;
    fin;

    inicia-ejecucion
        tomaYdeja;
        regresa;
        mientras junto-a-zumbador hacer inicio
        contar(0);
        Oeste;
        mientras frente-libre hacer avanza;
        Este;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        Norte;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        coge-zumbador;
        Sur;
        avanza;
        regresa;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
