iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion junta como inicio
        avanza;
        mientras frente-libre hacer inicio
            gira (1);
            mientras frente-libre hacer inicio
                si junto-a-zumbador entonces
                    coge-zumbador;
                avanza;
            fin;
            mientras algun-zumbador-en-la-mochila hacer
                deja-zumbador;
            gira (2);
            mientras frente-libre hacer
                avanza;
            gira (1);
            avanza;
        fin;
        gira (1);
        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces
                coge-zumbador;
            avanza;
        fin;
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
        gira (1);
    fin;
    define-nueva-instruccion cuenta (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta (sucede(n));
        fin
        sino inicio
            mientras no-orientado-al-sur hacer
                gira (1);
            mientras frente-libre hacer
                avanza;
            gira (1);
            mientras frente-libre hacer
                avanza;
            gira (1);
            repetir precede (n) veces
                avanza;
            deja-zumbador;
            mientras frente-libre hacer
                avanza;
            gira (1);
        fin;
    fin;
    define-nueva-instruccion altura como inicio
        si frente-libre entonces inicio
            si junto-a-zumbador entonces inicio
                cuenta (0);
                avanza;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                altura;
            fin
            sino inicio
                avanza;
                altura;
            fin;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                cuenta (0);
                gira (1);
            fin
            sino inicio
                gira (2);
                mientras frente-libre hacer
                    avanza;
                gira (3);
            fin;
        fin;
    fin;
    define-nueva-instruccion total (n) como inicio
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            total (sucede(n));
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                total (n);
            fin
            sino inicio
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    gira (3);
                    mientras frente-libre hacer
                        avanza;
                    repetir n veces
                        deja-zumbador;
                    deja-zumbador;
                fin
                sino inicio
                    gira (3);
                    mientras frente-libre hacer
                        avanza;
                    repetir n veces
                        deja-zumbador;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion vigas como inicio
        junta;
        altura;
        total (0);
    fin;
    inicia-ejecucion
        vigas;
        apagate;
    termina-ejecucion
finalizar-programa