iniciar-programa
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion orienta como inicio
        oeste;
        mientras frente-libre hacer avanza;
        este;
        mientras junto-a-zumbador y frente-libre hacer avanza;
    fin;

    define-nueva-instruccion final como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    oeste;
                    avanza;
                    final;
                    orienta;
                    repetir 3 veces deja-zumbador;
                fin sino inicio
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        final;
                        orienta;
                        repetir 2 veces deja-zumbador;
                    fin;
                fin;
            fin sino inicio
                este;
                avanza;
                final;
                orienta;
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion busqueda(n) como inicio
        si no si-es-cero (n) entonces inicio
            si no-junto-a-zumbador entonces inicio
                si orientado-al-norte entonces inicio
                    repetir 2 veces deja-zumbador;
                    si frente-bloqueado entonces inicio
                        final;
                        apagate;
                    fin;
                fin sino inicio
                    si orientado-al-oeste entonces inicio
                        deja-zumbador;
                    fin sino inicio
                        repetir 3 veces deja-zumbador;
                    fin;
                fin;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(precede(n));
                    sur;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(precede(n));
                    este;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(precede(n));
                    oeste;
                    avanza;
                fin;
                mientras junto-a-zumbador hacer coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion inf(n) como inicio
        norte;
        busqueda(n);
        inf(sucede(n));
    fin;

    inicia-ejecucion
    inf(1);
        apagate;
    termina-ejecucion
finalizar-programa
