iniciar-programa


define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;


    define-nueva-instruccion checa como inicio
        coge-zumbador;
        si no-junto-a-zumbador entonces inicio
            este;
            avanza;
            checa;
            deja-zumbador;
            si frente-libre entonces avanza;
        fin sino inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    checa;
                    repetir 2 veces deja-zumbador;
                    si frente-libre entonces avanza;
                fin sino inicio
                    oeste;
                    mientras frente-libre hacer avanza;
                    este;
                fin;
            fin sino inicio
                coge-zumbador;
                oeste;
                avanza;
                checa;
                repetir 3 veces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca(z) como inicio
        si no-junto-a-zumbador y no si-es-cero(z)  entonces inicio

        mientras no-orientado-al-sur hacer inicio
            deja-zumbador;
            gira-izquierda;
        fin;

        norte;
        si frente-bloqueado entonces inicio
            checa;
            apagate;
        fin;

            norte;
            si frente-libre entonces inicio
                avanza;
                busca(precede(z));
                sur;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                busca(precede(z));
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                busca(precede(z));
                este;
                avanza;
            fin;

        mientras junto-a-zumbador hacer coge-zumbador;

        fin;
    fin;

    define-nueva-instruccion mide(x) como inicio
        si frente-libre entonces inicio
            avanza;
            mide(sucede(x));
        fin sino inicio
            oeste;
            mientras no-junto-a-zumbador hacer avanza;
            norte;
            coge-zumbador;
            busca(sucede(sucede(x)));
        fin;
    fin;

    inicia-ejecucion
        deja-zumbador;
        oeste;
        mientras frente-libre hacer avanza;
        este;
        mide(0);

        apagate;
    termina-ejecucion
finalizar-programa
