iniciar-programa
define-prototipo-instruccion busqueda(x);
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion adelante(x) como inicio
    norte;
    si frente-libre entonces inicio
        avanza;
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            norte;
            busqueda(sucede(x));
            si orientado-al-sur y frente-bloqueado entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir 2 veces deja-zumbador;
                oeste;
                si frente-libre entonces avanza;
                sur;
            fin sino inicio
                si orientado-al-norte entonces inicio
                si junto-a-zumbador entonces coge-zumbador;
                sur;
                si frente-libre entonces avanza;
                norte;
                fin;
            fin;
        fin sino inicio
            sur;
            si frente-libre entonces avanza;
            norte;
        fin;
    fin;
fin;
define-nueva-instruccion izquierda(x) como inicio
    oeste;
    si frente-libre entonces inicio
        avanza;
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            norte;
            busqueda(sucede(x));
            si orientado-al-sur y frente-bloqueado entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                deja-zumbador;
                oeste;
                si frente-libre entonces avanza;
                sur;
            fin sino inicio
                si orientado-al-norte entonces inicio
                si junto-a-zumbador entonces coge-zumbador;
                este;
                si frente-libre entonces avanza;
                norte;
                fin;
            fin;
        fin sino inicio
            este;
            avanza;
            norte;
        fin;
    fin sino inicio
        norte;
    fin;
fin;
define-nueva-instruccion derecha(x) como inicio
    este;
    si frente-libre entonces inicio
        avanza;
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            norte;
            busqueda(sucede(x));
            si orientado-al-sur y frente-bloqueado entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir 3 veces deja-zumbador;
                oeste;
                si frente-libre entonces avanza;
                sur;
            fin sino inicio
                si orientado-al-norte entonces inicio
                si junto-a-zumbador entonces coge-zumbador;
                oeste;
                si frente-libre entonces avanza;
                norte;
                fin;
            fin;
        fin sino inicio
            oeste;
            avanza;
            norte;
        fin;
    fin sino inicio
        norte;
    fin;
fin;
define-nueva-instruccion busqueda(x) como inicio
    si frente-libre y orientado-al-norte entonces inicio
        si no junto-a-zumbador entonces deja-zumbador;
        si no orientado-al-sur entonces adelante(x);
        si no orientado-al-sur entonces izquierda(x);
        si no orientado-al-sur entonces derecha(x);
    fin sino inicio
        si frente-bloqueado y orientado-al-norte entonces inicio
            sur;
            busqueda(precede(x));
        fin sino inicio
            mientras frente-libre hacer avanza;
            oeste;
            mientras frente-libre hacer avanza;
            este;
            repetir x veces inicio
                si frente-libre y orientado-al-este entonces inicio
                    avanza;
                fin sino inicio
                    si no orientado-al-norte entonces inicio
                        norte;
                        si frente-libre entonces avanza;
                    fin;
                fin;
            fin;
            sur;
        fin;
    fin;
fin;
    inicia-ejecucion
        busqueda(0);
        si orientado-al-sur y frente-libre entonces inicio
            avanza;
            oeste;
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            norte;
            busqueda(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa

