iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion camino(a) como inicio
    mientras no-orientado-al-sur hacer gira(1);
    gira(2);
    repetir 3 veces inicio
        si no-orientado-al-este entonces inicio
            gira(1);
            si frente-libre entonces inicio
                avanza;
               si junto-a-zumbador entonces inicio
                   coge-zumbador;
                   si junto-a-zumbador entonces inicio
                       coge-zumbador;
                       si orientado-al-este entonces camino(1);
                       si orientado-al-sur entonces camino(2);
                       si orientado-al-oeste entonces camino(3);
                   fin sino inicio
                       deja-zumbador;
                       gira(2);
                       avanza;
                      gira(2);
                   fin;
               fin sino inicio
                    gira(2);
                    avanza;
                    gira(2);
                fin;
            fin;
        fin;
    fin;
    gira(2);
    mientras frente-libre hacer avanza;
    gira(2);
    mientras junto-a-zumbador y frente-libre hacer avanza;
    si no-junto-a-zumbador entonces repetir a veces deja-zumbador;
fin;

define-nueva-instruccion buscar como inicio
    repetir 100 veces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                camino(0);
                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
        avanza;
    fin;
fin;

define-nueva-instruccion bp(b) como inicio
    si no(si-es-cero(b)) entonces inicio
        si no-junto-a-zumbador entonces inicio
            repetir  2 veces deja-zumbador;
            repetir 4 veces inicio
                si frente-libre entonces inicio
                    avanza;
                    si no-junto-a-zumbador entonces inicio
                        bp(precede(b));
                    fin sino inicio
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            coge-zumbador;
                            si junto-a-zumbador entonces inicio
                                deja-zumbador;
                                mientras no-orientado-al-norte hacer gira(1);
                                mientras frente-libre hacer avanza;
                                gira(1);
                                mientras frente-libre hacer avanza;
                                gira(2);
                                buscar;
                            fin sino inicio
                                repetir 2 veces deja-zumbador;
                                bp(b);
                            fin;
                        fin sino inicio
                            deja-zumbador;
                            bp(b);
                        fin;
                    fin;
                    gira(2);
                    avanza;
                    gira(2);
                fin;
                gira(1);
            fin;
            repetir 2 veces coge-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion contador(c) como inicio
    repetir c veces inicio
        si junto-a-zumbador entonces inicio
            avanza;
        fin sino inicio
            bp(c);
            avanza;
        fin;
    fin;
fin;

define-nueva-instruccion espacio(d) como inicio
    si frente-libre entonces inicio
        avanza;
        espacio(sucede(d));
    fin sino inicio
        gira(2);
        repetir 2 veces inicio
            mientras frente-libre hacer avanza;
            gira(3);
        fin;
        contador(d);
    fin;
fin;

    inicia-ejecucion

    repetir 3 veces deja-zumbador;
    mientras no-orientado-al-oeste hacer gira(1);
    mientras frente-libre hacer avanza;
    gira(2);
    espacio(1);

        apagate;
    termina-ejecucion
finalizar-programa
