iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion marcar como inicio
        si orientado-al-oeste entonces inicio
            deja-zumbador;
        fin;
        si orientado-al-norte entonces inicio
            repetir 2 veces deja-zumbador;
        fin;
        si orientado-al-este entonces inicio
            repetir 3 veces deja-zumbador;
        fin;
        si orientado-al-sur entonces inicio
            repetir 4 veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion buscar(n) como inicio
        si no junto-a-zumbador y no si-es-cero(n) y (frente-libre o no orientado-al-norte) entonces inicio
            marcar;
            norte;
            si frente-libre entonces inicio
                avanza;
                buscar(precede(n));
                si frente-libre o no orientado-al-norte o junto-a-zumbador entonces inicio
                    sur;
                    avanza;
                fin;
            fin;
            oeste;
            si frente-libre y derecha-libre entonces inicio
                avanza;
                buscar(precede(n));
                si frente-libre o no orientado-al-norte o junto-a-zumbador entonces inicio
                    este;
                    avanza;
                fin;
            fin;
            este;
            si frente-libre y izquierda-libre entonces inicio
                avanza;
                buscar(precede(n));
                si frente-libre o no orientado-al-norte o junto-a-zumbador entonces inicio
                    oeste;
                    avanza;
                fin;
            fin;
            norte;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion avanzar(n) como inicio
        si si-es-cero (precede(n)) entonces inicio
            este;
            avanza;
        fin;
        si si-es-cero (precede(precede(n))) entonces inicio
            sur;
            avanza;
        fin;
        si si-es-cero (precede(precede(precede(n)))) entonces inicio
            oeste;
            avanza;
        fin;
    fin;

    define-nueva-instruccion regresar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            regresar(sucede(n));
        fin sino inicio
            avanzar(n);
            si junto-a-zumbador entonces inicio
                regresar(0);
            fin sino inicio
                oeste;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                este;
            fin;
            si no si-es-cero(n) y no si-es-cero(precede(precede(precede(precede(n))))) entonces inicio
                repetir n veces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar(n) como inicio
        si frente-libre entonces inicio
            avanza;
            contar(sucede(n));
        fin sino inicio
            oeste;
            mientras no junto-a-zumbador hacer inicio
                avanza;
            fin;
            coge-zumbador;
            sur;
            buscar(sucede(n));
            repetir 2 veces deja-zumbador;
            regresar(0);
        fin;
    fin;

    inicia-ejecucion
        deja-zumbador;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
        contar(0);

        apagate;
    termina-ejecucion
finalizar-programa
