iniciar-programa
    define-nueva-instruccion norte como inicio
      mientras no-orientado-al-norte hacer
        gira-izquierda;
    fin;

    define-nueva-instruccion sur como inicio
      mientras no-orientado-al-sur hacer
        gira-izquierda;
    fin;

    define-nueva-instruccion este como inicio
      mientras no-orientado-al-este hacer
        gira-izquierda;
    fin;

    define-nueva-instruccion oeste como inicio
      mientras no-orientado-al-oeste hacer
        gira-izquierda;
    fin;

    define-nueva-instruccion deja(n) como repetir n veces deja-zumbador;

    define-nueva-instruccion agarra(n) como repetir n veces coge-zumbador;

    define-nueva-instruccion limpia como inicio
      mientras junto-a-zumbador hacer coge-zumbador;
    fin;

    define-nueva-instruccion terminar como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
          coge-zumbador;
          si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
              limpia;
              sur;
              mientras frente-libre hacer avanza;
              oeste;
              mientras frente-libre hacer avanza;
              este;
            fin sino inicio
              oeste;
              avanza;
              terminar;
              limpia;
              deja(3);
              si frente-libre entonces avanza;
            fin;
          fin sino inicio
            sur;
            avanza;
            terminar;
            limpia;
            deja(2);
            si frente-libre entonces avanza;
          fin;
        fin sino inicio
          este;
          avanza;
          terminar;
          limpia;
          deja(1);
          si frente-libre entonces avanza;
        fin;
      fin sino inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
      fin;
    fin;          

    define-nueva-instruccion corre(n) como inicio
      norte;
      si frente-bloqueado entonces inicio
        terminar;
        apagate;
      fin;
      si no si-es-cero(n) entonces inicio
        norte;
        avanza;
        si no-junto-a-zumbador entonces inicio
          deja(2);
          corre(precede(n));
          agarra(2);
        fin;
        sur;
        avanza;
        este;
        si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces inicio
          deja(3);
          corre(precede(n));
          agarra(3);
        fin;
          oeste;
          avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
          avanza;
          si no-junto-a-zumbador entonces inicio
            deja(1);
            corre(precede(n));
            agarra(1);
          fin;
          este;
          avanza;
        fin;
      fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
      si frente-libre entonces inicio
        avanza;
        cuenta(sucede(n));
      fin sino inicio
        oeste;
        mientras no-junto-a-zumbador hacer avanza;
        este;
        corre(sucede(n));
      fin;
    fin;

    inicia-ejecucion
      deja(4);
      oeste;
      mientras frente-libre hacer inicio
        avanza;
      fin;
      este;
      cuenta(0);
      apagate;
    termina-ejecucion

finalizar-programa
