iniciar-programa
    define-nueva-instruccion deja(n) como repetir n veces deja-zumbador;
    define-nueva-instruccion levanta(n) como repetir n veces coge-zumbador;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion camino como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        oeste;
                        mientras frente-libre hacer avanza;
                        este;
                    fin sino inicio
                        oeste;
                        avanza;
                        camino;
                        deja(3);
                        si frente-libre entonces avanza;
                    fin;
                fin sino inicio
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        camino;
                        deja(2);
                        si frente-libre entonces avanza;
                    fin sino inicio
                        oeste;
                        deja(2);
                        si frente-libre entonces avanza;
                    fin;
                fin;
            fin sino inicio
                este;
                avanza;
                camino;
                deja-zumbador;
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca(pasos) como inicio
        norte;
        si frente-bloqueado entonces inicio
            sur;
            camino;
            apagate;
        fin;

        si no(si-es-cero(pasos)) entonces inicio
            norte;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    deja(2);
                    busca(precede(pasos));
                    levanta(2);
                fin;
                sur;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    deja(3);
                    busca(precede(pasos));
                    levanta(3);
                fin;
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    deja(1);
                    busca(precede(pasos));
                    levanta(1);
                fin;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(tamanio) como inicio
        si frente-libre entonces inicio
            avanza;
            cuenta(sucede(tamanio));
        fin sino inicio
            oeste;
            mientras no-junto-a-zumbador hacer avanza;
            busca(sucede(tamanio));
        fin;
    fin;

    inicia-ejecucion
        deja(4); (*marcamos la posicion inicial*)
        oeste;
        mientras frente-libre hacer avanza;
        este;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
