iniciar-programa

    define-nueva-instruccion norte como
    inicio
        mientras no-orientado-al-norte hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como
    inicio
        mientras no-orientado-al-sur hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como
    inicio
        mientras no-orientado-al-oeste hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-doble como
    inicio
        repetir 2 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina como
    inicio
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion jijole(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            jijole(sucede(x));
        fin
        sino
        inicio
            si si-es-cero(precede(x)) entonces
            inicio
               este;
               si frente-libre entonces
               inicio
                   avanza;
               fin;
               jijole(0);
               si (no-junto-a-zumbador y orientado-al-este) entonces
               inicio
               deja-zumbador;
               si frente-libre entonces
               inicio
                   avanza;
               fin;
               fin
               sino
               inicio
                   este;
               fin;
            fin
            sino
            inicio
                si si-es-cero(precede(precede(x))) entonces
                inicio
                   sur;
                   si frente-libre entonces
                   inicio
                       avanza;
                   fin;
                   jijole(0);
                   si (no-junto-a-zumbador y orientado-al-este) entonces
                   inicio
                   deja-zumbador;
                   deja-zumbador;
                   si frente-libre entonces
                   inicio
                       avanza;
                   fin;
                   fin
                   sino
                   inicio
                       este;
                   fin;
                fin
                sino
                inicio
                    si si-es-cero(precede(precede(precede(x)))) entonces
                    inicio
                       oeste;
                       si frente-libre entonces
                       inicio
                           avanza;
                       fin;
                       jijole(0);
                       si (no-junto-a-zumbador y orientado-al-este) entonces
                       inicio
                       deja-zumbador;
                       deja-zumbador;
                       deja-zumbador;
                       si frente-libre entonces
                       inicio
                           avanza;
                       fin;
                       fin
                       sino
                       inicio
                           este;
                       fin;
                    fin
                    sino
                    inicio
                        oeste;
                        camina;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion mover(x) como
    inicio
        si ((no(si-es-cero(x))) y (no(frente-bloqueado y orientado-al-norte))) entonces
        inicio
            norte;
            si frente-libre entonces
            inicio
                avanza;
                si no-junto-a-zumbador entonces
                inicio
                    repetir 2 veces
                    inicio
                        deja-zumbador;
                    fin;
                    mover(precede(x));
                    repetir 2 veces
                    inicio
                        coge-zumbador;
                    fin;
                fin;
                sur;
                avanza;
            fin;
            oeste;
            si frente-libre entonces
            inicio
                avanza;
                si no-junto-a-zumbador entonces
                inicio
                    repetir 1 veces
                    inicio
                        deja-zumbador;
                    fin;
                    mover(precede(x));
                    repetir 1 veces
                    inicio
                        coge-zumbador;
                    fin;
                fin;
                este;
                avanza;
            fin;
            este;
            si frente-libre entonces
            inicio
                avanza;
                si no-junto-a-zumbador entonces
                inicio
                    repetir 3 veces
                    inicio
                        deja-zumbador;
                    fin;
                    mover(precede(x));
                    repetir 3 veces
                    inicio
                        coge-zumbador;
                    fin;
                fin;
                oeste;
                avanza;
            fin;
        fin;
        si frente-bloqueado y orientado-al-norte entonces
        inicio
            sur;
            jijole(0);
            apagate;
        fin;
    fin;

    define-nueva-instruccion cuenta(x) como
    inicio
        si frente-libre entonces
        inicio
            avanza;
            cuenta(sucede(x));
        fin
        sino
        inicio
            oeste;
            mientras no-junto-a-zumbador hacer
            inicio
                avanza;
            fin;
            norte;
            mover(sucede(x));
        fin;
    fin;

    inicia-ejecucion
        deja-zumbador;
        oeste;
        camina;
        este;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
