iniciar-programa
define-nueva-instruccion gd como repetir 3 veces gira-izquierda;
define-nueva-instruccion mv como repetir 2 veces gira-izquierda;
define-nueva-instruccion busca como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces deja-zumbador
        sino inicio
            repetir 2 veces deja-zumbador;
            repetir 4 veces inicio
                si frente-libre entonces inicio
                    avanza;
                    busca;
                    repetir 2 veces gira-izquierda;
                    avanza;
                    repetir 2 veces gira-izquierda;
                fin;
            gira-izquierda;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion voltea(n) como inicio
    si derecha-libre entonces inicio
        gd;
        avanza;
        gd;
        mientras frente-libre hacer avanza;
        mv;
    fin
    sino inicio
        mv;
        repetir 2 veces inicio
            mientras frente-libre hacer avanza;
            gd;
        fin;
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir n veces deja-zumbador;
        apagate;
    fin;
fin;
define-nueva-instruccion cuenta(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin
        sino inicio
            deja-zumbador;
            si frente-libre entonces avanza
            sino voltea(n);
            cuenta(n);
        fin;
    fin
    sino inicio
        si frente-libre entonces avanza
        sino voltea(n);
        cuenta(n);
    fin;
fin;
inicia-ejecucion
busca;
mientras no-orientado-al-sur hacer gira-izquierda;
repetir 2 veces inicio
    mientras frente-libre hacer avanza;
    gd;
fin;
cuenta(0);
apagate;
termina-ejecucion
finalizar-programa
