iniciar-programa
    define-nueva-instruccion media-vuelta como repetir 2 veces gira-izquierda;
    define-nueva-instruccion gira-derecha como repetir 3 veces gira-izquierda;
    define-nueva-instruccion ve-a-la-esquina como
    inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        repetir 2 veces
        inicio
            mientras frente-libre hacer avanza;
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion regresa como
    inicio
        media-vuelta;
        avanza;
        media-vuelta;
    fin;
    define-nueva-instruccion verifica-y-deja(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            verifica-y-deja(precede(n));
            deja-zumbador;
        fin sino
        inicio
            si no(si-es-cero(n)) entonces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion cruz como
    inicio
        si frente-libre entonces
        inicio
            avanza;
            verifica-y-deja(9);
            si izquierda-libre entonces
            inicio
                gira-izquierda;
                avanza;
                verifica-y-deja(9);
                regresa;
                gira-derecha;
            fin;
        regresa;
        fin;
    fin;
    define-nueva-instruccion marcar-contiguas como
    inicio
        repetir 4 veces
        inicio
            cruz;
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion cuenta(n) como
    inicio
        si no(si-es-cero(n)) entonces
        inicio
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                cuenta(precede(n));
                deja-zumbador;
            fin;
        fin sino
        inicio
            marcar-contiguas;
        fin;
    fin;
    define-nueva-instruccion siguiente-columna como
    inicio
        si orientado-al-norte entonces
        inicio

            si derecha-libre entonces
            inicio
                gira-derecha;
                avanza;
                gira-derecha;
            fin;
        fin sino
        inicio
            si orientado-al-sur entonces
            inicio

                si izquierda-libre entonces
                inicio
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion busca-una-mina como
    inicio
        si (orientado-al-norte y frente-bloqueado y derecha-bloqueada) o
           (orientado-al-sur y frente-bloqueado y izquierda-bloqueada) entonces
        inicio
        fin sino
        inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces
            inicio
                cuenta(9);
                si frente-libre entonces
                inicio
                    avanza;
                    si frente-bloqueado y junto-a-zumbador entonces cuenta(9);
                fin;
            fin;
            si frente-bloqueado entonces
            inicio
                si frente-bloqueado y izquierda-bloqueada y orientado-al-sur entonces apagate;
                si frente-bloqueado y derecha-bloqueada y orientado-al-norte entonces apagate;
                siguiente-columna;
            fin;
            busca-una-mina;
        fin;
    fin;
    inicia-ejecucion
        ve-a-la-esquina;
        gira-izquierda;
        busca-una-mina;
        si junto-a-zumbador entonces cuenta(9);
        apagate;
    termina-ejecucion
finalizar-programa



