iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion ir11 como inicio
        oeste;
        corre;
        sur;
        corre;
    fin;
    define-nueva-instruccion piramide(x) como inicio
        si no si-es-cero(x) entonces inicio
            norte;
            repetir x veces inicio
                deja-zumbador;
                si frente-libre entonces avanza;
            fin;
            sur;
            corre;
            este;
            si frente-libre entonces avanza;
            piramide(precede(x));
        fin;
    fin;
    define-nueva-instruccion quita(n) como inicio
        si junto-a-zumbador entonces inicio
            repetir n veces coge-zumbador;
            quita(sucede(n));
        fin sino inicio
            si no si-es-cero(n) entonces inicio
                este;
                piramide(precede(n));
            fin;
        fin;
    fin;
    inicia-ejecucion
        ir11;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        quita(0);
        apagate;
    termina-ejecucion
finalizar-programa
