iniciar-programa
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion dividir como inicio
        si frente-libre entonces inicio
            repetir 2 veces avanza;
            dividir;
            avanza;
        fin
        sino repetir 2 veces gira-izquierda;
    fin;
    define-nueva-instruccion asegura como inicio
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        si (izquierda-bloqueada y derecha-bloqueada) y frente-bloqueado entonces inicio
            deja-zumbador;
            apagate;
        fin
        sino este;
        mientras derecha-bloqueada y frente-libre hacer avanza;
        si derecha-bloqueada entonces inicio
            oeste;
            dividir;
            deja-zumbador;
            apagate;
        fin;
    fin;
    define-nueva-instruccion principio como inicio
        asegura;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;
    define-nueva-instruccion linea como inicio
        dividir;
        deja-zumbador;
        principio;
        mientras derecha-bloqueada y frente-libre hacer avanza;
        si derecha-libre entonces inicio
            sur;
            avanza;
        fin
        sino apagate;
        principio;
    fin;
    inicia-ejecucion
        principio;
        mientras frente-libre o derecha-libre hacer
        linea;
        apagate;
    termina-ejecucion
finalizar-programa
