iniciar-programa
define-nueva-instruccion gira-derecha como
inicio
    repetir 3 veces gira-izquierda;
fin;
define-nueva-instruccion colocar-resultado como
inicio
    mientras no-orientado-al-sur hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-izquierda;
    avanza;
    gira-derecha;
    avanza;
    gira-derecha;
    mientras frente-libre hacer avanza;
    gira-derecha;
fin;
define-nueva-instruccion multiplica-b(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        multiplica-b(n);
        repetir n veces inicio
            deja-zumbador;
        fin;
    fin
    sino inicio
        colocar-resultado;
    fin;
fin;
define-nueva-instruccion multiplica-a(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        multiplica-a(sucede(n));
    fin
    sino inicio
        avanza;
        multiplica-b(n);
    fin;
fin;
define-nueva-instruccion ve-al-dividendo como
inicio
    mientras no-orientado-al-sur hacer gira-izquierda;
    avanza;
    gira-izquierda;
    avanza;
    gira-izquierda;
    avanza;
fin;
define-nueva-instruccion ve-al-cociente como
inicio
    gira-izquierda;
    avanza;
    avanza;
    gira-izquierda;
    mientras izquierda-libre y frente-libre hacer avanza;
fin;
define-nueva-instruccion divide(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        repetir n veces
        inicio
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
            fin
            sino inicio
                mientras no-orientado-al-este hacer gira-izquierda;
                si izquierda-bloqueada entonces avanza;
                deja-zumbador;
                avanza;
            fin;
        fin;
        si junto-a-zumbador entonces
        inicio
            divide(n);
            deja-zumbador;
        fin
        sino inicio
            si orientado-al-este entonces
            inicio
                gira-izquierda; gira-izquierda;
                mientras frente-libre hacer avanza;
                gira-izquierda;
                avanza;
                gira-izquierda;
                avanza;
                repetir n veces inicio
                    deja-zumbador;
                    avanza;
                fin;
                ve-al-cociente;
            fin
            sino inicio
                gira-derecha;
                avanza;
                gira-izquierda;
                avanza;
                gira-izquierda;
                mientras izquierda-libre y frente-libre hacer avanza;
                deja-zumbador;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion cuenta(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        cuenta(sucede(n));
    fin
    sino inicio
        repetir n veces deja-zumbador;
        ve-al-dividendo;
        divide(n);
    fin;
fin;
define-nueva-instruccion residuo como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        avanza;
        residuo;
        deja-zumbador;
    fin
    sino inicio
        gira-izquierda;
        avanza;
        gira-izquierda;
        mientras frente-libre hacer
        inicio
            si junto-a-zumbador entonces coge-zumbador;
            avanza;
        fin;
        gira-izquierda;
        avanza;
    fin;
fin;
    inicia-ejecucion
        gira-izquierda;
        avanza;
        gira-derecha;
        avanza;
        gira-izquierda;
        avanza;
        gira-izquierda;
        avanza;
        gira-derecha;
        multiplica-a(0);
        gira-derecha;
        repetir 2 veces avanza;
        gira-izquierda;
        avanza;
        cuenta(0);
        gira-izquierda; gira-izquierda;
        avanza;
        gira-derecha;
        avanza;
        gira-izquierda;
        mientras junto-a-zumbador hacer avanza;
        gira-izquierda; gira-izquierda;
        avanza;
        gira-izquierda;
        avanza;
        gira-izquierda;
        avanza;
        residuo;
        gira-izquierda;
        avanza;
        mientras junto-a-zumbador hacer
        inicio
            coge-zumbador;
            avanza;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa