iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion multi2(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            multi2(x);
            repetir x veces deja-zumbador;
        fin sino
        inicio
            este;
            avanza;
            sur;
            avanza;
            oeste;
            avanza;
        fin;
    fin;

    define-nueva-instruccion multi(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            multi(sucede(n));
        fin sino
        inicio
            avanza;
            multi2(n);
        fin;
    fin;


    define-nueva-instruccion arriba(n) como
    inicio
        si no si-es-cero(n) entonces
        inicio
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                arriba(precede(n));
            fin sino
            inicio
                sur;
                avanza;
                repetir n veces deja-zumbador;
            fin;
        fin sino
        inicio
            este;
            avanza;
            norte;
            avanza;
            oeste;
            avanza;
            deja-zumbador;
            este;
            avanza;
            sur;
            avanza;
            oeste;
            avanza;
            norte;
        fin;
    fin;

    define-nueva-instruccion abajo(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            abajo(precede(n));
        fin sino repetir n veces deja-zumbador;
    fin;

    define-nueva-instruccion div(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            div(sucede(n));
        fin sino
        inicio
            sur;
            avanza;
            este;
            avanza;
            norte;
            avanza;
            mientras orientado-al-norte hacer arriba(n);
            si junto-a-zumbador entonces abajo(n);
        fin;
    fin;

    define-nueva-instruccion todo como
    inicio
        avanza;
        norte;
        repetir 3 veces avanza;
        oeste;
        avanza;
        sur;
        multi(0);
        este;
        repetir 2 veces avanza;
        norte;
        avanza;
        div(0);
    fin;


    inicia-ejecucion
        todo;
        apagate;
    termina-ejecucion
finalizar-programa
