iniciar-programa
    define-nueva-instruccion Norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion orientar como inicio
        avanza;
        Norte;
        repetir 2 veces avanza;
        gira(1);
        avanza;
        gira(3);
    fin;

    define-nueva-instruccion multi(m) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multi(m);
        fin
        sino inicio
            gira(3);
            avanza;
            gira(3);
            repetir 2 veces avanza;
            gira(3);
            avanza;
        fin;
         repetir m veces deja-zumbador;
    fin;

    define-nueva-instruccion multiplicacion(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multiplicacion(sucede(n));
        fin
        sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                multi(n);
            fin;
        fin;
    fin;

    define-nueva-instruccion cociente como inicio
        gira(2);
        avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        gira(1);
        avanza;
        gira(1);
        repetir 2 veces avanza;
        gira(1);
        avanza;
        deja-zumbador;
        avanza;
        gira(1);
        repetir 2 veces avanza;
        gira(1);
        avanza;
        gira(1);
        avanza;
    fin;

    define-nueva-instruccion residuo como inicio
        coge-zumbador;
        gira(2);
        avanza;
        gira(2);
        deja-zumbador;
        avanza;
    fin;

    define-nueva-instruccion div(m) como inicio
        mientras junto-a-zumbador hacer inicio
            repetir m veces inicio
                si junto-a-zumbador entonces inicio
                    residuo;
                fin
                sino inicio
                    apagate;
                fin;
            fin;
            cociente;
        fin;
    fin;

    define-nueva-instruccion dividir(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            dividir(sucede(n));
        fin
        sino inicio
            avanza;
            gira-izquierda;
            avanza;
            gira-izquierda;
            avanza;
            si junto-a-zumbador entonces inicio
                div(n);
            fin;
        fin;
    fin;

    inicia-ejecucion
        orientar;
        multiplicacion(0);
        si orientado-al-norte entonces inicio
            gira(3);
            repetir 2 veces avanza;
            gira(3);
            avanza;
            dividir(0);
        fin
        sino inicio
            repetir 2 veces gira-izquierda;
            repetir 2 veces avanza;
            gira-izquierda;
            avanza;
            repetir 2 veces gira-izquierda;
            dividir(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
