iniciar-programa
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;
    define-nueva-instruccion divisor(d) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            divisor(sucede(d));
        fin sino inicio
            repetir d veces inicio
                deja-zumbador;
            fin;
            sur;
            avanza;
            oeste;
            avanza;
            repetir d veces inicio
                deja-zumbador;
            fin;
            este;
            avanza;
            norte;
            avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion divide(x) como inicio
        mientras junto-a-zumbador hacer inicio
            repetir precede(x) veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    sur;
                    avanza;
                    deja-zumbador;
                    norte;
                    avanza;
                    este;
                fin;
            fin;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                sur;
                avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
                este;
                avanza;
                deja-zumbador;
                oeste;
                avanza;
                norte;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion dividendo(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            dividendo(sucede(x));
        fin sino inicio
            repetir x veces inicio
                deja-zumbador;
            fin;
            sur;
            avanza;
            este;
            avanza;
            norte;
            avanza;
            divisor(0);
            este;
            divide(x);
        fin;
    fin;
    define-nueva-instruccion lugar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            lugar;
            deja-zumbador;
        fin sino inicio
            este;
            avanza;
            norte;
            avanza;
        fin;
    fin;
    define-nueva-instruccion cociente como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cociente;
            deja-zumbador;
        fin sino inicio
            norte;
            avanza;
            avanza;
            oeste;
            avanza;
        fin;
    fin;
    define-nueva-instruccion multiplicador(m) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multiplicador(sucede(m));
        fin sino inicio
            este;
            avanza;
            repetir m veces deja-zumbador;
            oeste;
            avanza;
            sur;
            repetir m veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion por(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            por(n);
            repetir n veces deja-zumbador;
        fin sino inicio
            este;
            avanza;
            sur;
            avanza;
            oeste;
            avanza;
        fin;
    fin;
    define-nueva-instruccion posicion como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            posicion;
            deja-zumbador;
        fin sino inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion multiplicar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multiplicar(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            avanza;
            multiplicador(0);
            por(n);
            este;
            avanza;
            norte;
            avanza;
            oeste;
            posicion;
        fin;
    fin;
    inicia-ejecucion
        avanza;
        norte;
        repetir 3 veces avanza;
        oeste;
        avanza;
        sur;
        multiplicar(0);
        este;
        repetir 2 veces avanza;
        dividendo(0);
        sur;
        avanza;
        oeste;
        avanza;
        lugar;
        sur;
        avanza;
        este;
        avanza;
        cociente;
        apagate;
    termina-ejecucion
finalizar-programa
