iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion salta como inicio
            mientras no-orientado-al-norte hacer gira(1);
            mientras derecha-bloqueada hacer avanza;
            gira(3);
            avanza;
            gira(3);
            mientras frente-libre hacer avanza;
            gira(1);
    fin;
    define-nueva-instruccion pasa(m) como inicio
        si orientado-al-este entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                pasa(m);
                deja-zumbador;
            fin
            sino si frente-libre entonces inicio
                avanza;
                pasa(sucede(m));
                avanza;
            fin
            sino inicio
                salta;
                repetir m veces avanza;
                gira(2);
            fin;
        fin
        sino inicio
        fin;
    fin;
    inicia-ejecucion
        mientras no orientado-al-este hacer gira(1);
        pasa(0);
        apagate;
    termina-ejecucion
finalizar-programa
