iniciar-programa
    define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer inicio
           gira-izquierda;
       fin;
    fin;
    define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer inicio
           gira-izquierda;
       fin;
    fin;
    define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer inicio
           gira-izquierda;
       fin;
    fin;
    define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer inicio
           gira-izquierda;
       fin;
    fin;
    define-nueva-instruccion camina como inicio
        mientras frente-libre hacer inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion ir-1-1 como inicio
        norte;
        camina;
        oeste;
        camina;
        sur;
        camina;
    fin;
    define-nueva-instruccion llenar-1 como inicio
        este;
        mientras frente-libre hacer inicio
            deja-zumbador;
            avanza;
        fin;
        deja-zumbador;
        ir-1-1;
        este;
    fin;

    define-nueva-instruccion pasar-pared como inicio
        si orientado-al-este entonces inicio
            norte;
            mientras derecha-bloqueada y frente-libre hacer inicio
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
            fin;
            sur;
            camina;
        fin;
        si orientado-al-oeste entonces inicio
            norte;
            mientras izquierda-bloqueada y frente-libre hacer inicio
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
            fin;
            sur;
            camina;
        fin;
    fin;
    define-nueva-instruccion recoger(n) como inicio
        este;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoger(sucede(n));
        fin sino inicio
            camina;
            pasar-pared;
            este;
            mientras junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
            ir-1-1;
            pasar-pared;
            ir-1-1;
            este;
            mientras no-junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            si junto-a-zumbador entonces inicio
                recoger(0);
            fin;
        fin;
    fin;
    define-nueva-instruccion tomar-1 como inicio
        este;
        mientras junto-a-zumbador hacer inicio
            avanza;
        fin;
        oeste;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador y frente-libre hacer inicio
                coge-zumbador;
                avanza;
            fin;
            si frente-bloqueado entonces inicio
                coge-zumbador;
            fin;
            apagate;
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
            fin;
            mientras junto-a-zumbador y frente-libre hacer inicio
                coge-zumbador;
                avanza;
            fin;
            si frente-bloqueado entonces inicio
                coge-zumbador;
            fin;
            apagate;
        fin;
    fin;
    inicia-ejecucion
        llenar-1;
        recoger(0);
        pasar-pared;
        tomar-1;
        apagate;
    termina-ejecucion
finalizar-programa
