iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como inicio
        mientras no orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no orientado-al-sur hacer inicio
            gira-izquierda;
        fin;             
    fin;

    define-nueva-instruccion cruza como inicio
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
        mientras derecha-bloqueada hacer inicio
            avanza;
        fin;
        este;
        avanza;
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion regresa como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
        mientras izquierda-bloqueada hacer inicio
            avanza;
        fin;
        oeste;
        avanza;
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion junta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            junta(n);
            deja-zumbador;
        fin sino inicio
            cruza;
            repetir n veces inicio
                avanza;
            fin;

        fin;
    fin;

    define-nueva-instruccion pasa(n) como inicio
        si frente-bloqueado y no junto-a-zumbador entonces inicio
            apagate;
        fin;
        si no junto-a-zumbador y frente-libre entonces inicio
            avanza;
            pasa(sucede(n));
        fin sino inicio
        junta(n);
        fin;
    fin;

    inicia-ejecucion
        este;
        mientras frente-libre hacer inicio
            pasa(0);
            regresa;
        fin;
        si frente-bloqueado y junto-a-zumbador entonces inicio
            pasa(0);
        fin;    
        apagate;
    termina-ejecucion
finalizar-programa
