iniciar-programa
define-nueva-instruccion orientar-este como inicio
    mientras no-orientado-al-este hacer
        gira-izquierda;
fin;

define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
fin;

define-nueva-instruccion media-vuelta como inicio
        gira-izquierda;
        gira-izquierda;
fin;

define-nueva-instruccion avanzar(x) como inicio
   si no si-es-cero(x) entonces inicio
       avanza;
       avanzar(precede(x));
   fin;
fin;



define-nueva-instruccion vete-a-poner(x) como inicio
    mientras frente-libre hacer
        avanza;
    gira-izquierda;
    mientras derecha-bloqueada hacer
        avanza;
    gira-derecha;
    avanza;
    gira-derecha;
    mientras frente-libre hacer
        avanza;
    gira-izquierda;
    avanzar(x);


fin;
define-nueva-instruccion recoge(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        recoge(x);
        deja-zumbador;
    fin
    sino inicio
        vete-a-poner(x);
    fin;
fin;




define-nueva-instruccion regresa como inicio
    media-vuelta;
    mientras frente-libre hacer
        avanza;
    gira-derecha;
    mientras izquierda-bloqueada hacer
        avanza;
    gira-izquierda;
    mientras frente-libre hacer
        avanza;
    gira-izquierda;
    mientras frente-libre hacer
        avanza;
   gira-izquierda;


fin;

define-nueva-instruccion solucion(x) como inicio


    si frente-libre y no-junto-a-zumbador entonces inicio
        avanza;
        solucion(sucede(x));
    fin
    sino inicio
    (*si los zumbadores estn junto a la pared*)
        si frente-bloqueado y no-junto-a-zumbador entonces
            apagate
         sino
        recoge(x);
    fin;
fin;

    inicia-ejecucion
    orientar-este;
    mientras frente-libre o junto-a-zumbador hacer inicio
        solucion(0);
        regresa;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
