iniciar-programa
define-nueva-instruccion media-vuelta como
inicio
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion gira-derecha como
inicio
    gira-izquierda;
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion cruzar como
inicio
    mientras frente-libre hacer avanza;
    mientras no-orientado-al-norte hacer gira-izquierda;
    mientras derecha-bloqueada y frente-libre hacer avanza;
    gira-derecha;
    avanza;
    gira-derecha;
    mientras frente-libre hacer avanza;
    gira-izquierda;
fin;
define-nueva-instruccion cruzar-dos como
inicio
    mientras no-orientado-al-sur hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-derecha;
    mientras frente-libre hacer avanza;
    mientras no-orientado-al-norte hacer gira-izquierda;
    mientras izquierda-bloqueada y frente-libre hacer avanza;
    gira-izquierda;
    avanza;
    gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-derecha;
    mientras frente-libre hacer avanza;
    media-vuelta;
fin;
define-nueva-instruccion contar-numeros(m) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        contar-numeros(sucede(m));
    fin
    sino inicio
        gira-izquierda;
        avanza;
        gira-derecha;
        repetir m veces deja-zumbador;
        gira-derecha;
        avanza;
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion contar(n) como
inicio
    si no-junto-a-zumbador y frente-libre entonces
    inicio
        avanza;
        contar(sucede(n));
    fin
    sino inicio
        contar-numeros(0);
        si frente-libre entonces
        inicio
            cruzar;
            gira-izquierda;
            avanza;
            gira-derecha;
            repetir n veces avanza;
            deja-zumbador;
            cruzar-dos;
        fin;
    fin;
fin;
define-nueva-instruccion extra como
inicio
    si frente-libre entonces
    inicio
        avanza;
        extra;
        avanza;
    fin
    sino inicio
        cruzar;
        gira-izquierda;
        avanza;
        gira-derecha;
    fin;
fin;
define-nueva-instruccion numero(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        numero(sucede(n));
    fin
    sino inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        cruzar;
        gira-izquierda;
        avanza;
        gira-derecha;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            gira-derecha;
            avanza;
            gira-derecha;
            repetir n veces deja-zumbador;
        fin;
        cruzar-dos;
    fin;
fin;
define-nueva-instruccion pasar como
inicio
    gira-izquierda;
    avanza;
    gira-derecha;
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    si frente-bloqueado y no-junto-a-zumbador entonces apagate;
    numero(0);
fin;
define-nueva-instruccion contar-extras(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        contar-extras(sucede(n));
    fin
    sino inicio
        cruzar;
        repetir n veces deja-zumbador;
    fin;
fin;
    inicia-ejecucion
        mientras no-orientado-al-este hacer gira-izquierda;
        si frente-bloqueado entonces
        inicio
            contar-extras(0);
            apagate;
        fin;
        mientras frente-libre hacer contar(0);
        gira-izquierda;
        avanza;
        gira-derecha;
        si junto-a-zumbador entonces
        inicio
            media-vuelta;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            avanza;
            gira-izquierda;
            extra;
            deja-zumbador;
            cruzar-dos;
        fin
        sino inicio
            media-vuelta;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            avanza;
            gira-izquierda;
        fin;
        mientras frente-libre hacer pasar;
        apagate;
    termina-ejecucion
finalizar-programa 