iniciar-programa
    define-nueva-instruccion orientate-norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion orientate-sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion orientate-este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion orientate-oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion coge-zumbadores como
        inicio
            si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    coge-zumbadores;
                fin;
        fin;
    define-nueva-instruccion deja-zumbadores como
        inicio
            si algun-zumbador-en-la-mochila entonces
                inicio
                    deja-zumbador;
                    deja-zumbadores;
                fin;
        fin;
    define-nueva-instruccion lleva como
        inicio
            orientate-este;
            mientras frente-libre hacer avanza;
            orientate-norte;
            mientras derecha-bloqueada hacer avanza;
            orientate-este;
            avanza;
            orientate-sur;
            mientras frente-libre hacer avanza;
            orientate-este;
            mientras junto-a-zumbador hacer avanza;
            deja-zumbadores;
        fin;
    define-nueva-instruccion regresa como
        inicio
            orientate-oeste;
            mientras frente-libre hacer avanza;
            orientate-norte;
            mientras izquierda-bloqueada hacer avanza;
            orientate-oeste;
            avanza;
            orientate-sur;
            mientras frente-libre hacer avanza;
            orientate-oeste;
            mientras frente-libre hacer avanza;
        fin;
    define-nueva-instruccion encuentra como
        inicio
            orientate-este;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces
                inicio
                    coge-zumbadores;
                    lleva;
                    regresa;
                    encuentra;
                fin;
            si no junto-a-zumbador o frente-bloqueado entonces apagate;
        fin;
    inicia-ejecucion
        inicio
            encuentra;
        fin;
    termina-ejecucion
finalizar-programa
