iniciar-programa
 DEFINE-NUEVA-INSTRUCCION NORTE COMO INICIO
  MIENTRAS NO-ORIENTADO-AL-NORTE HACER INICIO
   GIRA-IZQUIERDA;
  FIN;
 FIN;
 DEFINE-NUEVA-INSTRUCCION SUR COMO INICIO
  MIENTRAS NO-ORIENTADO-AL-SUR HACER INICIO
   GIRA-IZQUIERDA;
  FIN;
 FIN;
 DEFINE-NUEVA-INSTRUCCION ESTE COMO INICIO
  MIENTRAS NO-ORIENTADO-AL-ESTE HACER INICIO
   GIRA-IZQUIERDA;
 FIN;
FIN;
 DEFINE-NUEVA-INSTRUCCION OESTE COMO INICIO
  MIENTRAS NO-ORIENTADO-AL-OESTE HACER INICIO
   GIRA-IZQUIERDA;
  FIN;
 FIN;
 DEFINE-NUEVA-INSTRUCCION LLEGAR-A-2-9 COMO INICIO
  AVANZA;
  ESTE;
  REPETIR 8 VECES AVANZA;
  NORTE;
 FIN;
 DEFINE-NUEVA-INSTRUCCION COGE COMO INICIO
  MIENTRAS JUNTO-A-ZUMBADOR HACER INICIO
   MIENTRAS JUNTO-A-ZUMBADOR HACER INICIO
    COGE-ZUMBADOR;
   FIN;
   AVANZA;
  FIN;
 FIN;
 DEFINE-NUEVA-INSTRUCCION DEJA COMO INICIO
  SUR;
  MIENTRAS FRENTE-LIBRE HACER INICIO
   AVANZA;
  FIN;
  MIENTRAS ALGUN-ZUMBADOR-EN-LA-MOCHILA HACER INICIO
   DEJA-ZUMBADOR;
  FIN;
 FIN;
 DEFINE-NUEVA-INSTRUCCION SIG-DIGITO COMO INICIO
  OESTE;
  AVANZA;
  NORTE;
 FIN;
 DEFINE-NUEVA-INSTRUCCION REGRESA COMO INICIO
  ESTE;
  REPETIR 4 VECES INICIO
   AVANZA;
  FIN;
 NORTE;
FIN;
 DEFINE-NUEVA-INSTRUCCION DEJA-DIEZ COMO INICIO
  NORTE;
  AVANZA;
  MIENTRAS JUNTO-A-ZUMBADOR HACER INICIO
   AVANZA;
  FIN;
  MIENTRAS NO-JUNTO-A-ZUMBADOR Y ALGUN-ZUMBADOR-EN-LA-MOCHILA HACER INICIO
   REPETIR 10 VECES INICIO
    DEJA-ZUMBADOR;
   FIN;
   AVANZA;
  FIN;
  SUR;
  MIENTRAS FRENTE-LIBRE HACER INICIO
   AVANZA;
  FIN;
  NORTE;
 FIN;
 DEFINE-NUEVA-INSTRUCCION VACIA COMO INICIO
  MIENTRAS ALGUN-ZUMBADOR-EN-LA-MOCHILA HACER INICIO
   DEJA-ZUMBADOR;
  FIN;
 FIN;
 DEFINE-NUEVA-INSTRUCCION COGE-DIEZ COMO INICIO
  REPETIR 9 VECES INICIO
   SI JUNTO-A-ZUMBADOR ENTONCES INICIO
    COGE-ZUMBADOR;
   FIN;
  FIN;
  SI JUNTO-A-ZUMBADOR ENTONCES INICIO
   COGE-ZUMBADOR;
   DEJA-DIEZ;
  FIN
  SINO INICIO
   VACIA;
  FIN;

FIN;
 DEFINE-NUEVA-INSTRUCCION TOMA-DECENAS COMO INICIO
  NORTE;
  AVANZA;
  MIENTRAS JUNTO-A-ZUMBADOR HACER INICIO
   COGE-ZUMBADOR;
   AVANZA;
  FIN;
  SUR;
  MIENTRAS FRENTE-LIBRE HACER INICIO
   AVANZA;
  FIN;
  OESTE;
  AVANZA;
  VACIA;
  NORTE;
 FIN;
    inicia-ejecucion
        LLEGAR-A-2-9;
        REPETIR 4 VECES INICIO
         COGE;
         DEJA;
         SIG-DIGITO;
        FIN;
        COGE;
        DEJA;
        REGRESA;
        REPETIR 5 VECES INICIO
         REPETIR 10 VECES INICIO
          COGE-DIEZ;
         FIN;
         VACIA;
         TOMA-DECENAS;
        FIN;
        apagate;
    termina-ejecucion
finalizar-programa

