iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion recoge como inicio
       mientras no-orientado-al-sur hacer inicio
            norte;
            mientras junto-a-zumbador hacer inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                avanza;
            fin;
            sur;
            mientras frente-libre hacer avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            este;
            avanza;
            si no-junto-a-zumbador entonces sur;
        fin;
    fin;
    define-nueva-instruccion quita como inicio
      mientras junto-a-zumbador hacer inicio
        repetir 10 veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin sino inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                sal-de-instruccion;
            fin;
        fin;
        avanza;
        deja-zumbador;
        norte;
        avanza;
        este;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        sur;
        avanza;
        oeste;
      fin;
    fin;
    inicia-ejecucion
        avanza;
        repetir 3 veces gira-izquierda;
        repetir 4 veces avanza;
        recoge;
        oeste;
        avanza;
        mientras junto-a-zumbador hacer inicio
            quita;
            avanza;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
