iniciar-programa
define-nueva-instruccion gira-d como repetir 3 veces gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion sumar-columna como
inicio
mientras junto-a-zumbador hacer
inicio
mientras junto-a-zumbador hacer coge-zumbador;
avanza;
fin;
fin;

define-nueva-instruccion pasar-decenas como
inicio
    coge-zumbador;
    oeste;
    avanza;
    deja-zumbador;
    este;
    avanza;
    norte;
    avanza;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    sur;
    avanza;
    norte;
fin;

define-nueva-instruccion acomodar-decenas como
inicio
    sur;
    mientras frente-libre hacer avanza;
    norte;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    mientras junto-a-zumbador hacer
    inicio
        repetir 9 veces si junto-a-zumbador entonces coge-zumbador;
        si junto-a-zumbador entonces pasar-decenas;
    fin;
fin;

define-nueva-instruccion contar-unidades como
inicio
    norte;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    oeste;
    avanza;
    norte;
fin;



    inicia-ejecucion
    norte;
    avanza;
    este;
    repetir 8 veces avanza;
    norte;
    mientras junto-a-zumbador hacer
    inicio
        sumar-columna;
        acomodar-decenas;
        contar-unidades;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
