iniciar-programa
    define-nueva-instruccion primer-numero como inicio
        avanza;
        repetir 3 veces gira-izquierda;
        mientras no-junto-a-zumbador hacer avanza;
        mientras junto-a-zumbador hacer avanza;
        repetir 2 veces gira-izquierda;
        avanza;
        repetir 3 veces gira-izquierda;
    fin;
    define-nueva-instruccion suma como inicio
        repetir 5 veces inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces avanza;
            fin;
            repetir 2 veces gira-izquierda;
            mientras frente-libre hacer avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            repetir 3 veces gira-izquierda;
            avanza;
            repetir 3 veces gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion regresa-a-posicion como inicio
        repetir 3 veces gira-izquierda;
        mientras no-junto-a-zumbador hacer avanza;
        mientras junto-a-zumbador hacer avanza;
        repetir 2 veces gira-izquierda;
        avanza;
        repetir 3 veces gira-izquierda;
    fin;
    define-nueva-instruccion diez-en-diez como inicio
        mientras junto-a-zumbador hacer inicio
            repetir 10 veces si junto-a-zumbador entonces coge-zumbador;
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                repetir 2 veces gira-izquierda;
                mientras frente-libre hacer avanza;
                repetir 2 veces gira-izquierda;
            fin
            sino inicio
                repetir 9 veces si algun-zumbador-en-la-mochila entonces deja-zumbador;
                si ningun-zumbador-en-la-mochila entonces inicio
                    gira-izquierda;
                    avanza;
                    repetir 3 veces gira-izquierda;
                fin
                sino inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    avanza;
                    mientras junto-a-zumbador hacer avanza;
                    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                    repetir 2 veces gira-izquierda;
                    mientras frente-libre hacer avanza;
                    repetir 3 veces gira-izquierda;
                    avanza;
                    repetir 3 veces gira-izquierda;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion reubicate como inicio
        gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 2 veces gira-izquierda;
        repetir 8 veces avanza;
        gira-izquierda;
    fin;
    define-nueva-instruccion reordena-resultado como inicio
        repetir 5 veces inicio
            avanza;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                avanza;
            fin;
            gira-izquierda;
            avanza;
            gira-izquierda;
            mientras frente-libre hacer avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            repetir 2 veces gira-izquierda;
        fin;
    fin;
    inicia-ejecucion
        primer-numero;
        suma;
        regresa-a-posicion;
        diez-en-diez;
        reubicate;
        reordena-resultado;
        apagate;
    termina-ejecucion
finalizar-programa
