iniciar-programa

    define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion media-vuelta como inicio
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion quita-si-tiene-dos como inicio
        coge-zumbador;
        si no-junto-a-zumbador entonces
            deja-zumbador;
    fin;

    define-nueva-instruccion quita(Que) como inicio
        avanza;
        mientras junto-a-zumbador hacer inicio
            mientras junto-a-zumbador hacer inicio
                si si-es-cero(Precede(Que)) entonces
                    coge-zumbador
                sino
                    quita-si-tiene-dos;
                si frente-libre entonces
                    avanza;
            fin;

            si orientado-al-norte entonces inicio
                gira-derecha;
                avanza;
                gira-derecha;

                si junto-a-zumbador entonces inicio
                    si si-es-cero(Precede(Que)) entonces
                        coge-zumbador
                    sino
                        quita-si-tiene-dos;
                fin;

                avanza;
            fin
            sino inicio
                gira-izquierda;
                avanza;
                gira-izquierda;

                si junto-a-zumbador entonces inicio
                    si si-es-cero(Precede(Que)) entonces
                        coge-zumbador
                    sino
                        quita-si-tiene-dos;
                fin;

                avanza;
            fin;

        fin;

        mientras no-orientado-al-sur hacer
            gira-izquierda;

        mientras frente-libre hacer
            avanza;

        gira-derecha;

        mientras frente-libre hacer
            avanza;

        gira-derecha;
    fin;

    define-nueva-instruccion QuitaZumbadores(n) como inicio
        si no si-es-cero(n) entonces inicio
            coge-zumbador;
            QuitaZumbadores(Precede(n));
        fin;
    fin;

    define-nueva-instruccion DejaZumbadoresYRestalos(num) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            DejaZumbadoresYRestalos(Sucede(num));
        fin
        sino inicio
            avanza;
            QuitaZumbadores(num);
        fin;
    fin;

    inicia-ejecucion
        quita(2);

        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;

        quita(1);

        gira-derecha;
        avanza;
        avanza;

        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;

        media-vuelta;
        avanza;
        avanza;

        mientras junto-a-zumbador hacer
            coge-zumbador;

        media-vuelta;
        avanza;

        DejaZumbadoresYRestalos(0);

        gira-izquierda;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;

        media-vuelta;
        avanza;

        mientras junto-a-zumbador hacer
            coge-zumbador;

        gira-derecha;
        avanza;
        avanza;

        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;

        apagate;
    termina-ejecucion
finalizar-programa
