iniciar-programa
    define-nueva-instruccion orientadoEste como inicio
      mientras no-orientado-al-este hacer inicio
        gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion orientadoOeste como inicio
       mientras no-orientado-al-oeste hacer inicio
         gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion orientadoNorte como inicio
       mientras no-orientado-al-Norte hacer inicio
         gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion orientadoSur como inicio
       mientras no-orientado-al-sur hacer inicio
         gira-izquierda;
      fin;
    fin;

    define-nueva-instruccion camina como inicio
      mientras  frente-libre hacer inicio
         avanza;
      fin;
    fin;

    




    define-nueva-instruccion recogeLinea como inicio
      orientadoNorte;
      mientras junto-a-zumbador hacer inicio
         coge-zumbador;
         avanza;
      fin;
      orientadoSur;
      camina;
      orientadoEste;
    fin;



    define-nueva-instruccion dejaLinea como inicio
       si algun-zumbador-en-la-mochila entonces inicio
          deja-zumbador
       fin;
       mientras algun-zumbador-en-la-mochila y frente-libre hacer inicio
          avanza;
          deja-zumbador;
       fin;
    fin;


    define-nueva-instruccion sube1Renglon como inicio
      si orientado-al-este entonces inicio
         orientadoNorte;
         avanza;
         orientadoOeste;
      fin
      sino inicio
         orientadoNorte;
         avanza;
         orientadoEste;
      fin;
    fin;


    inicia-ejecucion
        (*  esto se divide en 2 programas*)
        orientadoSur;
        camina;
        orientadoEste;
        recogeLinea;
        mientras frente-libre hacer inicio
           avanza;
           recogeLinea;
        fin;

        (*  aqui es como si fuera otro programa*)
       orientadoOeste;
       mientras algun-zumbador-en-la-mochila hacer inicio
         dejaLinea;
         sube1Renglon;
       fin;

        apagate;
    termina-ejecucion
finalizar-programa
