iniciar-programa
    define-nueva-instruccion media-vuelta como inicio
        repetir 2 veces inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion gira-derecha como inicio
        repetir 3 veces inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion acomodate como inicio
        si orientado-al-oeste entonces inicio
            media-vuelta;
        fin;
        si orientado-al-norte entonces inicio
            gira-derecha;
        fin;
        si orientado-al-sur entonces inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion recoge-ladrillos como inicio
        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin;
            avanza;
            si frente-bloqueado y orientado-al-este y izquierda-libre entonces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
                gira-izquierda;
                avanza;
                gira-izquierda;
            fin;
            si frente-bloqueado y orientado-al-oeste y derecha-libre entonces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
                gira-derecha;
                avanza;
                gira-derecha;
            fin;
            si frente-bloqueado y derecha-bloqueada y orientado-al-oeste entonces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
                gira-izquierda;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
            fin;
            si frente-bloqueado y izquierda-bloqueada entonces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
                media-vuelta;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                gira-izquierda;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion construye-muro como inicio
        gira-izquierda;
        mientras algun-zumbador-en-la-mochila hacer inicio
            mientras frente-libre hacer inicio
                si algun-zumbador-en-la-mochila entonces inicio
                    deja-zumbador;
                fin;
                avanza;
            fin;
            si frente-bloqueado y orientado-al-este entonces inicio
                si algun-zumbador-en-la-mochila entonces inicio
                    deja-zumbador;
                fin;
                gira-izquierda;
                avanza;
                gira-izquierda;
            fin;
            si frente-bloqueado y orientado-al-oeste entonces inicio
                si algun-zumbador-en-la-mochila entonces inicio
                    deja-zumbador;
                fin;
                gira-derecha;
                avanza;
                gira-derecha;
            fin;
        fin;
    fin;
    inicia-ejecucion
        acomodate;
        recoge-ladrillos;
        construye-muro;
        apagate;
    termina-ejecucion
finalizar-programa
