iniciar-programa
define-nueva-instruccion media como repetir 2 veces gira-izquierda;
define-nueva-instruccion derecha como repetir 3 veces gira-izquierda;
define-nueva-instruccion moverizq como
inicio
gira-izquierda;
avanza;
fin;
define-nueva-instruccion moverder como
inicio
derecha;
avanza;
fin;
define-nueva-instruccion moveratras como
inicio
media;
avanza;
fin;
define-nueva-instruccion llenalinea como
inicio
mientras no-junto-a-zumbador hacer
   inicio
   deja-zumbador;
   avanza;
   fin;
fin;
define-nueva-instruccion caminaapared como
inicio
mientras frente-libre hacer avanza;
fin;
define-nueva-instruccion cierracubiculo como
inicio
  caminaapared;
  moverder;
  deja-zumbador;
  moveratras;
  gira-izquierda;
  caminaapared;
  moverizq;
  gira-izquierda;
  llenalinea;
fin;
define-nueva-instruccion checacubiculo como
inicio
mientras no-junto-a-zumbador y frente-libre hacer avanza;
si junto-a-zumbador entonces cierracubiculo
sino inicio
moverder;
gira-izquierda;
fin;
fin;
define-nueva-instruccion iniciar como
inicio
  caminaapared;
  moveratras;
  gira-izquierda;
  si frente-bloqueado entonces
  inicio
     moverizq;
     si junto-a-zumbador entonces
     inicio
        moveratras;
        deja-zumbador;
        fin;      
     apagate;
     fin;
  moverizq;
  derecha;
  checacubiculo;
fin;
    inicia-ejecucion
    iniciar;
    mientras frente-libre hacer
    inicio
      avanza;
      moverizq;
      derecha;
      checacubiculo;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
