iniciar-programa
define-nueva-instruccion gira-derecha como
inicio
    repetir 3 veces gira-izquierda;
fin;
define-nueva-instruccion media-vuelta como
inicio
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion buscar como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si frente-libre entonces avanza;
            mientras junto-a-zumbador y frente-libre hacer
            inicio
                avanza;
            fin;
            deja-zumbador;
            deja-zumbador;
        fin
        sino inicio
        deja-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion regresar como
inicio
    mientras no-orientado-al-oeste hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    media-vuelta;
fin;
define-nueva-instruccion acomodar como
inicio
    si junto-a-zumbador y frente-libre  entonces
    inicio
        coge-zumbador;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            deja-zumbador;
            deja-zumbador;
            si frente-libre entonces avanza;
            acomodar;
        fin
        sino inicio
            regresar;
            deja-zumbador;
            si frente-libre entonces avanza;
            acomodar;
        fin;
    fin
    sino inicio
    si frente-libre entonces
    inicio
        avanza;
        acomodar;
    fin;
    fin;
fin;
define-nueva-instruccion regresar2 como
inicio
    mientras no-orientado-al-este hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    media-vuelta;
fin;
define-nueva-instruccion karelitas como
inicio
    si frente-libre entonces
    inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            regresar2;
            deja-zumbador;
            deja-zumbador;
            avanza;
            karelitas;
        fin;
    fin
    sino inicio
        avanza;
        karelitas;
    fin;
    fin;
fin;
define-nueva-instruccion colocar como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        si junto-a-zumbador entonces
        inicio
            mientras junto-a-zumbador y frente-libre hacer avanza;
            deja-zumbador;
            regresar;
            colocar;
        fin
        sino inicio
        deja-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion colocar2 como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        coge-zumbador;
        si junto-a-zumbador entonces
        inicio
            mientras junto-a-zumbador y frente-libre hacer avanza;
            deja-zumbador;
            deja-zumbador;
            regresar2;
            colocar2;
        fin
        sino inicio
        deja-zumbador;
        deja-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion buscar-este como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si frente-libre entonces avanza;
            mientras junto-a-zumbador y frente-libre hacer
            inicio
                avanza;
            fin;
            deja-zumbador;
            deja-zumbador;
        fin
        sino inicio
        si frente-libre entonces avanza;
         mientras junto-a-zumbador y frente-libre hacer
            inicio
                avanza;
            fin;
        deja-zumbador;
        fin;
    fin;
fin;
    inicia-ejecucion
        mientras no-orientado-al-este hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        media-vuelta;
        buscar-este;
        mientras no-orientado-al-oeste hacer
        inicio
            gira-izquierda;
        fin;
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
        media-vuelta;
        buscar;
        media-vuelta;
        mientras frente-libre hacer avanza;
        media-vuelta;
        avanza;
        acomodar;
        media-vuelta;
        karelitas;
        media-vuelta;
        colocar;
        mientras frente-libre hacer avanza;
        media-vuelta;
        colocar2;
        apagate;
    termina-ejecucion
finalizar-programa