iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;


    define-nueva-instruccion karelitas como
    inicio
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si junto-a-zumbador entonces
        inicio
            repetir 2 veces coge-zumbador;
            karelitas;
            repetir 2 veces deja-zumbador;
            si frente-libre entonces avanza;
         fin;
         oeste;
    fin;

   define-nueva-instruccion recreo como
   inicio
      mientras no-junto-a-zumbador y frente-libre hacer avanza;
      si frente-libre o (frente-bloqueado y junto-a-zumbador) entonces
       inicio
           si junto-a-zumbador entonces coge-zumbador;
           si junto-a-zumbador entonces
           inicio
               deja-zumbador;
               si frente-libre entonces avanza
               sino
               inicio
               repetir 2 veces gira-izquierda;
               karelitas;
               fin;
               recreo;
           fin sino
           inicio
               si frente-libre entonces avanza;
               recreo;
               deja-zumbador;
               si frente-libre entonces avanza;
           fin;
       fin sino
       inicio
       este;
       karelitas;
       mientras frente-libre hacer avanza;
       este;
   fin;
fin;


  define-nueva-instruccion formarse como
  inicio
      este;
      mientras frente-libre hacer avanza;
      oeste;
      recreo;
   fin;



    inicia-ejecucion
        formarse;
        apagate;
    termina-ejecucion
finalizar-programa
