iniciar-programa

define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion choca como mientras frente-libre hacer avanza;

define-nueva-instruccion posiciona como inicio
    oeste;
    choca;
    este;
fiN;

define-nueva-instruccion excepcion como inicio
    norte;
    si izquierda-bloqueada y derecha-bloqueada entonces inicio
        apagate;
    fin;
fin;

define-nueva-instruccion unosh como inicio
    oeste;
    choca;
    este;
    mientras junto-a-zumbador y frente-libre hacer inicio
        avanza;
    fin;
    deja-zumbador;
fin;



define-nueva-instruccion dosh como inicio
    este;
    choca;
    oeste;
    mientras junto-a-zumbador y frente-libre hacer inicio
        avanza;
    fin;
    repetir 2 veces deja-zumbador;
fin;

define-nueva-instruccion separa como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            separa;
            dosh;
        fin sino inicio
            separa;
            unosh;
        fin;
     fin sino inicio
         si frente-libre entonces inicio
             avanza;
             separa;
         fin;
     fin;
fin;


    inicia-ejecucion
        excepcion;
        posiciona;
        separa;

        apagate;
    termina-ejecucion
finalizar-programa
