iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion iniciodefila como inicio
        mientras no-orientado-al-oeste hacer gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;

    define-nueva-instruccion findefila como inicio
        mientras no-orientado-al-este hacer gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;

    define-nueva-instruccion hombre como inicio
        iniciodefila;
        mientras junto-a-zumbador hacer avanza;
        deja-zumbador;
    fin;

    define-nueva-instruccion mujer como inicio
        findefila;
        mientras junto-a-zumbador hacer avanza;
        repetir 2 veces deja-zumbador;
    fin;

    define-nueva-instruccion separa como inicio
        si (frente-libre o junto-a-zumbador) entonces inicio
            si (frente-libre y junto-a-zumbador) entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    avanza;
                    separa;
                    mujer;
                fin sino inicio
                    avanza;
                    separa;
                    hombre;
                fin;
            fin sino inicio
                si frente-libre entonces inicio
                    avanza;
                    separa;
                fin sino inicio
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            coge-zumbador;
                            separa;
                            mujer;
                        fin sino inicio
                            separa;
                            hombre;
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        iniciodefila;
        separa;
        apagate;
    termina-ejecucion
finalizar-programa
