iniciar-programa
    DEFINE-NUEvA-INSTRUCCION mediavuelta como inicio
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion orientar como inicio
        coge-zumbador;
        repetir 4 veces inicio
            si no junto-a-zumbador entonces inicio
                gira-izquierda;
                si frente-libre entonces inicio
                    avanza;
                    si no junto-a-zumbador entonces inicio
                        mediavuelta;
                        avanza;
                        mediavuelta;
                    fin;
                fin;
            fin;
        fin;
        si junto-a-zumbador entonces inicio
            mediavuelta;
            avanza;
            mediavuelta;
            deja-zumbador;
        fin sino inicio
            deja-zumbador;
            apagate;
        fin;
    fin;

    define-nueva-instruccion completar como inicio
        mediavuelta;
        avanza;
        deja-zumbador;
        mediavuelta;
        avanza;
    fin;

    define-nueva-instruccion recorrer como inicio
        mientras junto-a-zumbador hacer inicio
            (*llega hasta el final de la linea*)
            mientras junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            si no junto-a-zumbador entonces inicio
                mediavueltA;
                avanza;
                mediavuelta;
            fin;
            (*busca la siguiente linea a la izquierda y a la derecha*)
            coge-zumbador;
            gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                si no junto-a-zumbador entonces inicio
                    mediavuelta;
                    avanza;
                    si frente-libre entonces inicio
                        avanza;
                        si no junto-a-zumbador entonces inicio
                            mediavuelta;
                            avanza;
                            deja-zumbador;
                            apagate;
                        fin sino inicio
                            completar;
                        fin;
                    fin sino inicio
                        deja-zumbador;
                        apagate;
                    fin;
                fin sino inicio
                    completar;
                fin;
            fin sino inicio
                mediavuelta;
                si frente-libre entonces inicio
                    avanza;
                    si no junto-a-zumbador entonces inicio
                        mediavuelta;
                        avanzA;
                        deja-zumbador;
                        apagate;
                    fin sino inicio
                        completar;
                    fin;
                fin sino inicio
                    deja-zumbador;
                    apagate;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        orientar;
        recorrer;
        apagate;
    termina-ejecucion
finalizar-programa
